jbw@bucsb.UUCP (Joe Wells) (10/02/88)
Here is an interface to GNU Emacs that will either start a new emacs
process if none is already running, or will pass the command line
arguments to an existing emacs process. This includes a csh alias and
emacs-lisp code.
To resume a running process, the alias either calls emacsclient to
talk to an emacs server, or uses the csh fg command to resume a
stopped job. If it resumes a stopped job, it puts the command line
arguments in a file. To start a new process, the alias determines if
you are running under a windowing system or not.
The emacs-lisp code is only used when resuming a stopped job. It will
process any contents of a certain file as though they were command
line arguments.
Joe Wells
INTERNET: jbw%bucsf.bu.edu@bu-it.bu.edu
UUCP: ...!harvard!bu-cs!bucsf!jbw
;;----------------------resume.el------------------------------------
;; Process command line arguments from within a suspended Emacs job
;; Copyright (C) 1988 Free Software Foundation, Inc.
;; This file is not yet part of GNU Emacs, but soon will be.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY. No author or distributor
;; accepts responsibility to anyone for the consequences of using it
;; or for whether it serves any particular purpose or works at all,
;; unless he says so in writing. Refer to the GNU Emacs General Public
;; License for full details.
;; Everyone is granted permission to copy, modify and redistribute
;; GNU Emacs, but only under the conditions described in the
;; GNU Emacs General Public License. A copy of this license is
;; supposed to have been given to you along with GNU Emacs so you
;; can know your rights and responsibilities. It should be in a
;; file named COPYING. Among other things, the copyright notice
;; and this notice must be preserved on all copies.
;; by Joe Wells
;; jbw@bucsf.bu.edu (school year)
;; joew%uswest@boulder.colorado.edu (summer)
;; Stephan Gildea suggested bug fix (gildea@bbn.com).
;; Ideas from Michael DeCorte and other people.
;; For csh users, insert the following alias in your .cshrc file
;; (after removing the leading double semicolons):
;;
;;# The following line could be just EMACS=emacs, but this depends on
;;# your site.
;;set EMACS=/usr/public/xxemacs
;;set EMACS_PATTERN="^\[[0-9]\] . Stopped ............ $EMACS"
;;alias emacs \
;;' \\
;; jobs >! /tmp/jobs$$ \\
;; && grep "$EMACS_PATTERN" /tmp/jobs$$ >& /dev/null \\
;; && echo `pwd` \!* >! ~/.emacs_args && eval "%$EMACS" \\
;;|| test -S ~/.emacs_server && emacsclient \!* \\
;;|| test "$?DISPLAY" = 1 && eval "\$EMACS -i \!* &" \\
;;|| test "$?WINDOW_PARENT" = 1 && eval "emacstool -f emacstool-init \!* &" \\
;;|| eval "\$EMACS -nw \!*"'
;;
;; The alias works as follows:
;; 1. If there is a suspended emacs jobs that is a child of the
;; current shell, place its arguments in the ~/.emacs_args file and
;; resume it.
;; 2. Else if the ~/.emacs_server socket has been created, presume an
;; emacs server is running and attempt to connect to it. If no emacs
;; server is listening on the socket, this will fail.
;; 3. Else if the DISPLAY environment variable is set, presume we are
;; running under X Windows and start a new X Gnu Emacs process in the
;; background.
;; 4. Else if the WINDOW_PARENT environment variable is set, presume we
;; are running under Sunview and Suntools and start an emacstool
;; process in the background.
;; 5. Else start a regular emacs process.
;;
;; Notes:
;; "test -S" checks if a unix domain socket by that name exists.
;; The output of the "jobs" command is not piped directly into "grep"
;; because that would run the "jobs" command in a subshell.
;; Before resuming a suspended emacs, the current directory and all
;; command line arguments are placed in a file.
;; The command to run emacs is always preceded by a \ to prevent
;; possible alias loops.
;; The "-nw" switch in the last line is is undocumented, and it means
;; no windowing system.
;; Insert this in your .emacs file:
;;(setq suspend-resume-hook 'resume-process-args)
;;(setq suspend-hook 'empty-args-file)
;;(autoload 'empty-args-file "resume")
;;(autoload 'resume-process-args "resume")
;; Finally, put this in a file named "resume.el" in a lisp library
;; directory.
(defvar emacs-args-file (expand-file-name "~/.emacs_args")
"*This file is where arguments are placed for a suspended emacs job.")
(defvar emacs-args-buffer " *Command Line Args*"
"Buffer that is used by resume-process-args.")
(defun resume-process-args ()
"This should be called from inside of suspend-resume-hook. This
grabs the contents of the file whose name is stored in
emacs-args-file, and processes these arguments like command line
options."
(let ((start-buffer (current-buffer))
(args-buffer (get-buffer-create emacs-args-buffer))
length args)
(unwind-protect
(progn
(set-buffer args-buffer)
(erase-buffer)
;; get the contents of emacs-args-file
(condition-case ()
(let ((result (insert-file-contents emacs-args-file)))
(setq length (car (cdr result))))
;; the file doesn't exist, ergo no arguments
(file-error
(erase-buffer)
(setq length 0)))
(if (<= length 0)
(setq args nil)
;; get the arguments from the buffer
(goto-char (point-min))
(while (not (eobp))
(skip-chars-forward " \t\n")
(let ((begin (point)))
(skip-chars-forward "^ \t\n")
(setq args (cons (buffer-substring begin (point)) args)))
(skip-chars-forward " \t\n"))
;; arguments are now in reverse order
(setq args (nreverse args))
;; make sure they're not read again
(erase-buffer))
(write-buffer-to-file (current-buffer) emacs-args-file)
;; if nothing was in buffer, args will be null
(or (null args)
(setq default-directory (file-name-as-directory (car args))
args (cdr args)))
;; actually process the arguments
(command-line-1 args))
;; If the command line args don't result in a find-file, the
;; buffer will be left in args-buffer. So we change back to the
;; original buffer. The reason I don't just use
;; (let ((default-directory foo))
;; (command-line-1 args))
;; in the context of the original buffer is because let does not
;; work properly with buffer-local variables.
(if (eq (current-buffer) args-buffer)
(set-buffer start-buffer)))))
(defun empty-args-file ()
"This empties the contents of the file whose name is specified by
emacs-args-file."
(save-excursion
(set-buffer (get-buffer-create emacs-args-buffer))
(erase-buffer)
(write-buffer-to-file (current-buffer) emacs-args-file)))
(defun write-buffer-to-file (buffer file)
"Writes the contents of BUFFER into FILE, if permissions allow."
(if (not (file-writable-p file))
(error "No permission to write file %s" file))
(save-excursion
(set-buffer buffer)
(clear-visited-file-modtime)
(save-restriction
(widen)
(write-region (point-min) (point-max) file nil 'quiet))
(set-buffer-modified-p nil)))