eric@snark.uu.net (Eric S. Raymond) (09/13/89)
Do you guys want this for version 19?
; sccs.el -- a gnu-emacs package that makes SCCS comfortable to use
;
; You can blame this one on Eric S. Raymond (eric@snark.uu.net).
; It is loosely derived from an rcs mode written by Ed Simpson
; ({decvax, seismo}!mcnc!duke!dukecdu!evs) in years gone by
; and revised at MIT's Project Athena.
;;; User options
(defvar sccs-max-log-size 510
"*Maximum allowable size (chars) + 1 of an sccs log message.")
(defvar sccs-default-diff-flags '("-c")
"*If non-nil, default the diff in sccsdiff to use these flags.")
(defvar sccs-admin-base nil
"*Base sid for admin to use on new files. If nil, user will be queried.")
;;; Vars the user doesn't need to know about.
(defvar sccs-mode-map nil)
;;; Some helper functions
(defun sccs-name (file &optional letter)
"Return the sccs-file name corresponding to a given file"
(format "%sSCCS/%s.%s"
(concat (file-name-directory file))
(or letter "s")
(concat (file-name-nondirectory file))))
(defun sccs-lock-info (file index)
"Return the nth token in a file's SCCS-lock information"
(let
((pfile (sccs-name file "p")))
(and (file-exists-p pfile)
(save-excursion
(find-file pfile)
(auto-save-mode nil)
(replace-string " " "\n")
(goto-char (point-min))
(forward-line index)
(prog1
(buffer-substring (point) (progn (end-of-line) (point)))
(set-buffer-modified-p nil)
(kill-buffer (current-buffer)))
)
)
)
)
(defun sccs-locking-user (file)
"Return the name of the person currently holding a lock on FILE, nil if
there is no such person."
(sccs-lock-info file 2)
)
(defun sccs-locked-revision (file)
"Return the revision number currently locked for FILE, nil if none such."
(sccs-lock-info file 1)
)
(defmacro error-occurred (&rest body)
(list 'condition-case nil (cons 'progn (append body '(nil))) '(error t)))
;; There has *got* to be a better way to do this...
(defmacro chmod (perms file)
(list 'call-process "chmod" nil nil nil perms file))
;; the following functions do most of the real work
(defun sccs-get-version (file sid)
"For the given FILE, retrieve a copy of the version with given SID in
a tempfile. Return the tempfile name, or nil if no such version exists."
(let (oldversion vbuf)
(setq oldversion (sccs-name file (or sid "new")))
(setq vbuf (create-file-buffer oldversion))
(prog1
(if (not (error-occurred
(sccs-do-command vbuf "get" file
(and sid (concat "-r" sid))
"-p" "-s")))
(save-excursion
(set-buffer vbuf)
(write-region (point-min) (point-max) oldversion t 0)
oldversion)
)
(kill-buffer vbuf)
)
)
)
(defun sccs-mode-line (file)
"Set the mode line for an sccs buffer. FILE is the file being visited to
put in the modeline."
(setq mode-line-process
(if (file-exists-p (sccs-name file "p"))
(format " <SCCS: %s>" (sccs-locked-revision file))
""))
; force update of screen
(save-excursion (set-buffer (other-buffer)))
(sit-for 0)
)
(defun sccs-do-command (buffer command file &rest flags)
" Execute an sccs command, notifying the user and checking for errors."
(message (format "Running %s on %s..." command file))
(save-window-excursion
(set-buffer (get-buffer-create buffer))
(erase-buffer)
(while (and flags (not (car flags)))
(setq flags (cdr flags)))
(let
((default-directory (file-name-directory (or file "./"))))
(apply 'call-process command nil t nil
(append flags (and file (list (sccs-name file)))))
)
(goto-char (point-max))
(previous-line 1)
(if (looking-at "ERROR")
(error (format "Running %s on %s...failed" command file))
(message (format "Running %s on %s...done" command file))
)
)
(if file (sccs-mode-line file))
)
(defun sccs-tree-walk (func &rest optargs)
"Apply FUNC to each SCCS file under the default directory. If present,
OPTARGS are also passed."
(shell-command (concat
"find " default-directory " -print | grep 'SCCS/s\\.'"))
(set-buffer "*Shell Command Output*")
(goto-char (point-min))
(replace-string "SCCS/s." "")
(goto-char (point-min))
(if (eobp)
(error "No SCCS files under %s" default-directory))
(while (not (eobp))
(let ((file (buffer-substring (point) (progn (end-of-line) (point)))))
(apply func file optargs)
)
(forward-line 1)
)
)
;;; Here's the major entry point
(defun sccs (verbose)
"Tries to do the next logical SCCS operation on the file associated with the
current buffer. You must have an SCCS subdirectory in the same directory
as the file being operated on.
If the file is not already registered with SCCS, this does an admin -i
followed by a get -e.
If the file is registered and not locked by anyone, this does a get -e.
If the file is registered and locked by the calling user, this pops up a
buffer for creation of a log message, then does a delta -n on the file.
A read-only copy of the changed file is left in place afterwards.
If the file is registered and locked by someone else, an error message is
returned indicating who has locked it."
(interactive "P")
(if (buffer-file-name)
(let
(do-update revision owner
(file (buffer-file-name))
(sccs-file (sccs-name (buffer-file-name)))
(sccs-log-buf (get-buffer-create "*SCCS-Log*"))
(err-msg nil))
;; if there is no SCCS file corresponding, create one
(if (not (file-exists-p sccs-file))
(sccs-admin file (or
sccs-admin-base
(read-from-minibuffer "Base version: ")
)))
(cond
;; if there is no lock on the file, assert one and get it
((not (file-exists-p (sccs-name file "p")))
(progn
(sccs-get file t)
(revert-buffer nil t)
(sccs-mode-line file)
))
;; a checked-out version exists, but the user may not own the lock
((not (string-equal
(setq owner (sccs-locking-user file)) (user-login-name)))
(error "Sorry, %s has that file checked out", owner))
;; OK, user owns the lock on the file
(t (progn
;; if so, give luser a chance to save before delta-ing.
(if (and (buffer-modified-p)
(y-or-n-p (format "%s has been modified. Write it out? "
(buffer-name))))
(save-buffer))
(setq revision (sccs-locked-revision file))
;; user may want to set nonstandard parameters
(if verbose
(if (y-or-n-p
(format "Rev: %s Change revision level? " revision))
(setq revision (read-string "New revision level: "))))
;; OK, let's do the delta
(if
;; this excursion returns t if the new version was saved OK
(save-window-excursion
(pop-to-buffer (get-buffer-create "*SCCS*"))
(erase-buffer)
(set-buffer-modified-p nil)
(sccs-mode)
(message
"Enter log message. Type C-c C-c when done, C-c ? for help.")
(prog1
(and (not (error-occurred (recursive-edit)))
(not (error-occurred (sccs-delta file revision))))
(setq buffer-file-name nil)
(bury-buffer "*SCCS*")))
;; if the save went OK do some post-checking
(if (buffer-modified-p)
(error
"Delta-ed version of file does not match buffer!")
(progn
;; sccs-delta already turned off write-privileges on the
;; file, let's not re-fetch it unless there's something
;; in it that get would expand
(if (sccs-check-headers)
(sccs-get file nil))
(revert-buffer nil t)
(sccs-mode-line file)
)
))))))
(error "There is no file associated with buffer %s" (buffer-name))))
;;; These functions help sccs()
(defun sccs-admin (file sid)
"Checks a file into sccs. FILE is the unmodified name of the file. SID
should be the base-level sid to check it in under."
(sccs-do-command "*SCCS*" "admin" file
(concat "-i" file) (concat "-r" sid))
(chmod "-w" file)
)
(defun sccs-get (file writeable)
"Retrieve a locked copy of the latest delta of the given file."
(sccs-do-command "*SCCS*" "get" file (if writeable "-e")))
(defun sccs-delta (file &optional rev comment)
"Delta the file specified by FILE. REV is a string specifying the
new revision level (if nil increment the current level). The file is retained
with write permissions zeroed. COMMENT is a comment string; if omitted, the
contents of the current buffer up to point becomes the comment for this delta."
(if (not comment)
(progn
(goto-char (point-max))
(if (not (bolp)) (newline))
(newline)
(setq comment (buffer-substring (point-min) (1- (point)))))
)
(sccs-do-command "*SCCS*" "delta" file "-n"
(if rev (format "-r%s" rev))
(format "-y%s" comment))
(chmod "-w" file)
)
(defun sccs-abort ()
"Abort an sccs command."
(interactive)
(if (y-or-n-p "Abort the delta? ") (error "Delta aborted")))
(defun sccs-exit ()
"Leave the recursive edit of an sccs log message."
(interactive)
(if (< (buffer-size) sccs-max-log-size)
(progn
(copy-to-buffer sccs-log-buf (point-min) (point-max))
(exit-recursive-edit))
(progn
(goto-char sccs-max-log-size)
(error
"Log must be less than %d characters. Point is now at char %d."
sccs-max-log-size sccs-max-log-size)))
)
;; some additional entry point
(defun sccs-diff (&optional revno &rest flags)
"Compare the current version of the buffer with the last checked in
revision of the file, or, if given a prefix argument, with another revision."
(interactive (if current-prefix-arg
(list current-prefix-arg
(read-string "Revision to compare against: "))))
(let (old file)
(if
(setq old (sccs-get-version (buffer-file-name) revno))
(progn
(if (and (buffer-modified-p)
(y-or-n-p (format "%s has been modified. Write it out? "
(buffer-name))))
(save-buffer))
(setq file (buffer-file-name))
(pop-to-buffer (get-buffer-create "*SCCS*"))
(erase-buffer)
(apply 'call-process "diff" nil t nil
(append sccs-default-diff-flags flags (list old) (list file)))
(set-buffer-modified-p nil)
(goto-char (point-min))
(delete-file old)
)
)
)
)
(defun sccs-prs ()
"List the SCCS log of the current buffer in an emacs window"
(interactive)
(sccs-do-command "*SCCS*" "prs" buffer-file-name)
(pop-to-buffer (get-buffer-create "*SCCS*")))
;; miscellaneous other bindings for use while editing log messages
(defun sccs-insert-last-log ()
"Insert the log message of the last sccs check in at point."
(interactive)
(insert-buffer sccs-log-buf))
(defun sccs-mode ()
"Major mode for doing an sccs check in.
Calls the value of text-mode-hook then sccs-mode-hook.
Like Text Mode but with these additional comands:
C-c C-c proceed with check in
C-x C-s same as C-c C-c
C-c i insert log message from last check in
C-c a abort this check in
C-c ? show this message
Global user options:
sccs-max-log-size specifies the maximum allowable size
of a log message plus one.
sccs-default-diff-flags flags to pass to diff(1) when doing
sccs-prs commands, useful if you have
a context differ
"
(interactive)
(set-syntax-table text-mode-syntax-table)
(use-local-map sccs-mode-map)
(setq local-abbrev-table text-mode-abbrev-table)
(setq major-mode 'sccs-mode)
(setq mode-name "SCCS")
(run-hooks 'text-mode-hook 'sccs-mode-hook)
)
(if sccs-mode-map
nil
(setq sccs-mode-map (make-sparse-keymap))
(define-key sccs-mode-map "\C-c?" 'describe-mode)
(define-key sccs-mode-map "\C-ci" 'sccs-insert-last-log)
(define-key sccs-mode-map "\C-c\C-i" 'sccs-insert-last-log)
(define-key sccs-mode-map "\C-ca" 'sccs-abort)
(define-key sccs-mode-map "\C-c\C-a" 'sccs-abort)
(define-key sccs-mode-map "\C-c\C-c" 'sccs-exit)
(define-key sccs-mode-map "\C-x\C-s" 'sccs-exit)
)
(defvar sccs-headers-wanted '("%W%")
"*SCCS header keywords inserted into comments when sccs-insert-header
is executed")
(defvar sccs-insert-static t
"*Insert a static character string when inserting SCCS headers in C mode.")
(defun sccs-insert-headers ()
"Insert headers for use with the Source Code Control System
Headers desired are inserted at the start of the buffer, and are pulled from
the variable sccs-headers-wanted"
(interactive)
(save-excursion
(save-restriction
(widen)
(if (or (not (sccs-check-headers))
(y-or-n-p "SCCS headers already exist. Insert another set?"))
(progn
(goto-char (point-min))
(run-hooks 'sccs-insert-headers-hook)
(cond ((eq major-mode 'c-mode) (sccs-insert-c-header))
((eq major-mode 'lisp-mode) (sccs-insert-lisp-header))
((eq major-mode 'emacs-lisp-mode) (sccs-insert-lisp-header))
((eq major-mode 'scheme-mode) (sccs-insert-lisp-header))
(t (sccs-insert-generic-header))))))))
(defun sccs-insert-c-header ()
(let (st en)
(insert "/*\n")
(mapcar '(lambda (s)
(insert " *\t" s "\n"))
sccs-headers-wanted)
(insert " */\n\n")
(if (and sccs-insert-static
(not (string-match "\\.h$" (buffer-file-name))))
(progn
(insert "#ifndef lint\n"
"static char *sccsid")
;; (setq st (point))
;; (insert (file-name-nondirectory (buffer-file-name)))
;; (setq en (point))
;; (subst-char-in-region st en ?. ?_)
(insert " = \"%W%\";\n"
"#endif /* lint */\n\n")))
(run-hooks 'sccs-insert-c-header-hook)))
(defun sccs-insert-lisp-header ()
(mapcar '(lambda (s)
(insert ";;;\t" s "\n"))
sccs-headers-wanted)
(insert "\n")
(run-hooks 'sccs-insert-lisp-header-hook))
(defun sccs-insert-generic-header ()
(let* ((comment-start-sccs (or comment-start "#"))
(comment-end-sccs (or comment-end ""))
(dont-insert-nl-p (string-match "\n" comment-end-sccs)))
(mapcar '(lambda (s)
(insert comment-start-sccs "\t" s ""
comment-end-sccs (if dont-insert-nl-p "" "\n")))
sccs-headers-wanted)
(insert comment-start-sccs comment-end-sccs (if dont-insert-nl-p "" "\n"))))
(defun sccs-check-headers ()
"Check if the current file has any SCCS headers in it."
(interactive)
(save-excursion
(goto-char (point-min))
(re-search-forward "%[MIRLBSDHTEGUYFPQCZWA]%" (point-max) t)))
;;; Status-checking functions
(defun sccs-status (prefix legend)
"List all files underneath the current directory matching a prefix type"
(shell-command
(format "find . -print | grep 'SCCS/%s\\.'" prefix))
(if
(save-excursion
(set-buffer "*Shell Command Output*")
(if (= (point-max) (point-min))
(not (message
"No files are currently %s under %s"
legend default-directory))
(progn
(goto-char (point-min))
(insert
"The following files are currently " legend
" under " default-directory ":\n")
(replace-string (format "SCCS/%s." prefix) "")
)
)
)
(pop-to-buffer "*Shell Command Output*")
)
)
(defun sccs-pending ()
"List all files currently SCCS locked"
(interactive)
(sccs-status "p" "locked"))
(defun sccs-registered ()
"List all files currently SCCS registered"
(interactive)
(sccs-status "s" "registered"))
(defun sccs-version-diff (file rel1 rel2)
"Given a FILE registered under SCCS, report diffs between two stored deltas
REL1 and REL2 of an SCCS."
(pop-to-buffer (get-buffer-create "*SCCS*"))
(erase-buffer)
(sccs-vdiff file rel1 rel2)
(set-buffer-modified-p nil)
(goto-char (point-min))
)
(defun sccs-vdiff (file rel1 rel2 &optional flags)
"Compare two deltas into the current buffer"
(let (vers1 vers2)
(and
(setq vers1 (sccs-get-version file rel1))
(setq vers2 (sccs-get-version file rel2))
; (prog1
; (save-excursion
; (not (error-occurred
; (call-process "prs" nil t t
; (sccs-name file))))
; )
; )
(unwind-protect
(apply 'call-process "diff" nil t t
(append sccs-default-diff-flags flags (list vers1) (list vers2)))
(condition-case () (delete-file vers1) (error nil))
(condition-case () (delete-file vers2) (error nil))
)
)
)
)
(defun sccs-release-diff (rel1 rel2)
"Generate a complete report on diffs between versions REL1 and REL2 for all
SCCS files at or below default-directory. If REL2 is omitted or nil, the
comparison is done against the most recent version."
(interactive "sOlder version: \nsNewer version: ")
(if (string-equal rel1 "") (setq rel1 nil))
(if (string-equal rel2 "") (setq rel2 nil))
(shell-command (concat
"find " default-directory " -print | grep 'SCCS/s\\.'"))
(set-buffer "*Shell Command Output*")
(goto-char (point-min))
(replace-string "SCCS/s." "")
(goto-char (point-min))
(if (eobp)
(error "No SCCS files under %s" default-directory))
(let
((sccsbuf (get-buffer-create "*SCCS*")))
(save-excursion
(set-buffer sccsbuf)
(erase-buffer)
(insert (format "Diffs from %s to %s.\n\n"
(or rel1 "current") (or rel2 "current"))))
(while (not (eobp))
(let ((file (buffer-substring (point) (progn (end-of-line) (point)))))
(save-excursion
(set-buffer sccsbuf)
(set-buffer-modified-p nil)
(sccs-vdiff file rel1 rel2)
(if (buffer-modified-p)
(insert "\n"))
)
(forward-line 1)
)
)
(kill-buffer "*Shell Command Output*")
(pop-to-buffer sccsbuf)
(insert "\nEnd of diffs.\n")
(goto-char (point-min))
(replace-string (format "/SCCS/%s." rel1) "/")
(goto-char (point-min))
(replace-string (format "/SCCS/%s." rel2) "/new/")
(goto-char (point-min))
(replace-string "/SCCS/new." "/new/")
(goto-char (point-min))
(replace-regexp (concat "^*** " default-directory) "*** ")
(goto-char (point-min))
(replace-regexp (concat "^--- " default-directory) "--- ")
(goto-char (point-min))
(set-buffer-modified-p nil)
)
)
(defun sccs-dummy-delta (file sid)
"Make a dummy delta to the given FILE with the given SID"
(interactive "sFile: \nsRelease ID: ")
(if (not (sccs-locked-revision file))
(sccs-get file t))
;; Grottiness alert -- to get around SCCS's obsessive second-guessing we
;; have to mung the p-file
(save-excursion
(let ((pfile (sccs-name file "p")))
(chmod "u+w" pfile)
(find-file pfile)
(auto-save-mode nil)
(replace-regexp "^\\([0-9.]+\\) \\([0-9.]+\\)" (concat "\\1 " sid) t)
(write-region (point-min) (point-max) pfile t 0)
(chmod "u-w" pfile)
(set-buffer-modified-p nil)
(kill-buffer (current-buffer))
)
)
(sccs-delta file sid (concat "Release " sid))
(sccs-get file nil)
)
(defun sccs-delta-release (sid)
"Delta everything underneath the current directory to mark it as a release."
(interactive "sRelease: ")
(sccs-tree-walk 'sccs-dummy-delta sid)
(kill-buffer "*SCCS*")
)
;; sccs.el ends here
--
Eric S. Raymond = eric@snark.uu.net (mad mastermind of TMN-Netnews)