nigam%mwvms@MITRE.ARPA (01/27/88)
-------- >From: "The Radio Gnome" <V2002A%TEMPLEVM.BITNET@CUNYVM.CUNY.EDU> >Subject: getting current dir in dcl prompt > The logical thing to do would be: >$TEMP = "show default" >$SET PROMPT = 'TEMP' > >..but VMS will only take a string for SET PROMPTs argument >and the string must not have spaces in it. VMS complains about >"too many parameters" >:-{ Try $SET PROMPT='F$STRING(F$DIRECTORY()+">")' This works best if imbeded in a .COM file which you use to change directories; several such have appeared on DECUS tapes in the past. Incidentally, you can have spaces in your string, just enclose the whole thing in quotation marks, ie. $SET PROMPT="Hello World" Alok C. Nigam nigam@mitre.arpa -------
cfchiesa@bsu-cs.UUCP (Sir Xetwnk) (02/07/88)
In article <8801271320.AA15259@mitre.arpa>, nigam%mwvms@MITRE.ARPA writes: > -------- > >From: "The Radio Gnome" <V2002A%TEMPLEVM.BITNET@CUNYVM.CUNY.EDU> > >Subject: getting current dir in dcl prompt > > The logical thing to do would be: > >$TEMP = "show default" > >$SET PROMPT = 'TEMP' > > > >..but VMS will only take a string for SET PROMPTs argument > >and the string must not have spaces in it. VMS complains about > >"too many parameters" >:-{ Yes it WILL take strings containing spaces. In just about EVERY instane where THIS IS A STRING WITH SPACES is "not accepted" by VMS, "THIS IS A STRING WITH SPACES" IS accepted. The secret is that you have to put quotes around the string. You can quite easily get away with $ SET PROMPT:"Prompt with spaces in it> " just like that. Chris <><><><><><><><><><><><><><><><><><><><><><><><><><><><> Chris Chiesa <><><><><> <> {ihpn4|seismo}!{iuvax|pur-ee}!bsu-cs!cfchiesa <> <> cfchiesa@bsu-cs.UUCP <> <><><><><><><><><><><><><><><><><><><><><><><><><><><><><><><><><><><><><><><><>
woo@pioneer.arpa (Alex Woo) (02/07/88)
Here is yet another set of command files for getting the current
directory in the DCL prompt.
The symbol definitions assume that the command files reside in the top
most user directory. They could just as well reside in SYS$MANAGER:
or some such and avoid useless redundancy.
Alex Woo
$!=============================cut here=============================
$!
$! here are the symbols to be added to your login.com
$!
$ MkDir :== @sys$login:mkdir !CREATE /DIRECTORY
$ rmdir :== @sys$login:rmdir !remove directory (almost)
$ CD :== @sys$login:ChDirDO !p1=dirname p2=disk
$ DO*wn :== @sys$login:ChDirDO !p1=leaf of current node
$ UP :== @sys$login:ChDirUp !no args
$ OV*er :== @sys$login:ChDirOV !p1=leaf of the node 1 up
$ UPOV*er :== @sys$login:ChdUpov !p1=leaf of the node 2 up
$ HO*ME :== @sys$login:ChDirHo !no args
$ SD :== @sys$login:ChDir !p1=same as SD, for systems without SD.exe
$! SD :== @sys$login:ChDirSD !p1=same as SD, also sets prompt
$ TOP :== @sys$login:ChDirTo !no args
$!=============================cut here=============================
$! CHDIRHO.COM p1=subdirectory path {optional}
$! Purpose: changes working directory to user's root dir or a subdir of root
$! History: original design <a.woo> mods by <dbs> feb87
$! eval := write sys$output
$ node = f$trnlnm("sys$node")-"::"
$! eval "NODE: "+node
$ user = f$user()
$! eval "USER: "+user
$ if p1 .NES. "" then goto path
$ set def sys$login:
$! sho def
$ set prompt = "''node'''user' "
$ exit
$ path:
$ set def sys$login:
$ set def [.'p1]
$ direc = f$directory() + " "
$ set prompt = "''node'''direc'"
$ set def [-.'P1']
$ direc = f$directory() + " "
$ node = f$trnlnm("sys$node")-"::"
$ set prompt = "''node'''direc'"
$!=============================cut here=============================
$!chdir.com <acw>
$ if "''p1'" .NES. "" then goto _set_directory
$ write sys$output "Usage: changedir directory-name {disk:}"
$ goto _set_prompt
$_set_directory:
$ set def 'p2'['P1']
$_set_prompt:
$ DIREC = f$directory() + " "
$ node = f$trnlnm("sys$node")-"::"
$ set prompt = "''node'''direc'"
$!=============================cut here=============================
$!chdirdo.com (rename to do*wn) <acw>
$!
$ set def [.'p1']
$ direc = f$directory() + " "
$ node = f$trnlnm("sys$node")-"::"
$ set prompt = "''node'''direc'"
$!=============================cut here=============================
$!chdirsd.com (rename to sd)
$ @sys$system:sd 'p1'
$ DIREC = f$directory()
$ node = f$trnlnm("sys$node")-"::"
$ set prompt = "''node'''direc' "
$!=============================cut here=============================
$! chdirto.com change name to 'top'
$! move to top of current directory tree <acw>
$!
$ DIREC = f$directory()
$ node = f$trnlnm("sys$node")-"::"
$ POS = f$locate(".",DIREC)
$ ! if "." not found, POS = length of string, and default already top-level
$ IF POS .EQ. f$length(DIREC) then EXIT
$ TOP = f$extract(0,POS,DIREC)
$ set def 'TOP']
$ set prompt = "''node'''TOP'] "
$!=============================cut here=============================
$! chdirup.com move up one level in directory tree
$! change name to UP <acw>
$ set def [-]
$ DIREC = f$directory() + " "
$ node = f$trnlnm("sys$node")-"::"
$ set prompt = "''node'''direc'"
$!=============================cut here=============================
$! chdupov.com change name to upov*er in login
$! move up and over <acw>
$ set def [--.'P1']
$ DIREC = f$directory()
$ direc = f$directory() + " "
$ node = f$trnlnm("sys$node")-"::"
$ set prompt = "''node'''direc'"
$!=============================cut here=============================
$! mkdir.com
$crea/dir [.'p1']
$!=============================cut here=============================
$!rmdir.com
$! this isn't quite right but it works 90% of the time
$set prot=w:rwed 'p1'.dir
$on error then continue
$set prot [.'p1'...]*.*;*
$on error then continue
$del [.'p1'...]*.*;*
$del 'p1'.dir;