reingold@m.cs.uiuc.edu (02/03/89)
My abject apologies: The calendar.el I posted here a day or so ago
contained some special characters that causes the file to get corrupted
as it goes over the net to some (but not all) locations. Below is an
uncorrupted version, with the special characters replaced by appropriately
quoted forms that should cause no trouble.
My thanks to the (many) people who pointed out the difficulty.
The program can also be obtained by anonymous ftp to a.cs.uiuc.edu where
it's in the file calendar.el.
Byte-compile it for reasonable response time.
------------------------------------------------------------------------------
;; Calendar and diary functions.
;; Copyright (C) 1988, 1989 Free Software Foundation, Inc.
;; This file is part of GNU Emacs.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY. No author or distributor
;; accepts responsibility to anyone for the consequences of using it
;; or for whether it serves any particular purpose or works at all,
;; unless he says so in writing. Refer to the GNU Emacs General Public
;; License for full details.
;; Everyone is granted permission to copy, modify and redistribute
;; GNU Emacs, but only under the conditions described in the
;; GNU Emacs General Public License. A copy of this license is
;; supposed to have been given to you along with GNU Emacs so you
;; can know your rights and responsibilities. It should be in a
;; file named COPYING. Among other things, the copyright notice
;; and this notice must be preserved on all copies.
;; This collection of functions implements a calendar window and diary. It
;; generates a calendar for the current month, together with the previous and
;; coming months, or for any other three-month period. The calendar can be
;; shifted forward and backward in the window to show months in the past or
;; future; the cursor can move forward and backward by days, weeks, or months,
;; making it possible, for instance, to jump to the date a specified number
;; of days, weeks, or months from the date under the cursor. The user can
;; display a list of holidays and other notable days for the period shown.
;; The user can also specify that dates having corresponding diary entries
;; (in a file that the user specifies) be marked; the diary entries for any
;; date can be viewed in a separate window. The diary and the notable days
;; can be viewed independently of the calendar.
;; Comments, corrections, and improvements should be sent to
;; Edward M. Reingold Department of Computer Science
;; (217) 333-6733 University of Illinois at Urbana-Champaign
;; reingold@a.cs.uiuc.edu 1304 West Springfield Avenue
;; Urbana, Illinois 61801
;; GNU Emacs users too numerous to list pointed out a variety of problems
;; with earlier forms of the `infinite' sliding calendar and suggested some
;; of the features included in this package. Especially significant in this
;; regard was the suggestion of mark-diary-entries and view-diary-entries,
;; together ideas for their implementation, by
;; Michael S. Littman Cognitive Science Research Group
;; (201)-829-5155 Bell Communications Research
;; mlittman@wind.bellcore.com 445 South St. Box 1961 (2L-331)
;; Morristown, NJ 07960-1961
;; The algorithms of Maimonides for the Hebrew calendar were implemented by
;; Nachum Dershowitz Department of Computer Science
;; (217) 333-4219 University of Illinois at Urbana-Champaign
;; nachum@a.cs.uiuc.edu 1304 West Springfield Avenue
;; Urbana, Illinois 61801
(defvar view-diary-entries-initially nil
"*If T, the diary entries for the current date will be displayed on entry.
The diary is displayed in another window when the calendar is first displayed,
if the current date is visible. The number of days of diary entries displayed
is governed by the variable number-of-diary-entries.")
(defvar number-of-diary-entries 1
"*Specifies how many days of diary entries are to be displayed.
For example, if the default value 1 is used, then only the current day's
diary entries will be displayed. If the value 2 is used, then both the
current day's and the next day's entries will be displayed. The value can
also be a vector such as [0 2 2 2 2 4 1]; this value will cause no diary
entries to be displayed on Sunday, the current date's and the next day's
diary entries to be displayed Monday through Thursday, Friday through
Monday's entries to be displayed on Friday, and only Saturday's entries to
be displayed on Saturday.")
(defvar mark-diary-entries-in-calendar nil
"*If T, dates with diary entries will be marked in the calendar window.
The marking symbol is diary-entry-marker.")
(defvar diary-entry-marker "+"
"*The symbol used to mark dates that have diary entries.")
(defvar view-calendar-holidays-initially nil
"*If T, the holidays for the current three month period will be displayed
on entry. The holidays are displayed in another window when the calendar is
first displayed.")
(defvar mark-holidays-in-calendar nil
"*If T, dates of holidays will be marked in the calendar window.
The marking symbol is calendar-holiday-marker.")
(defvar calendar-holiday-marker "*"
"*The symbol used to mark notable in the calendar.")
(defvar initial-calendar-window-hook nil
"*List of functions to be called when the calendar window is first opened.
The functions invoked are called after the calendar window is opened, but
once opened is never called again. Leaving the calendar with the `q' command
and reentering it will cause these functions to be called again.")
(defvar today-visible-calendar-hook nil
"*List of functions called whenever the current date is visible.
This can be used, for example, to replace today's date with asterisks; a
function calendar-star-date is included for this purpose:
(setq today-visible-calendar-hook 'calendar-star-date)
It could also be used to mark the current date with `*'; a function is also
provided for this:
(setq today-visible-calendar-hook 'calendar-mark-today)
The corresponding variable today-invisible-calendar-hook is the list of
functions called when the calendar function was called when the current
date is not visible in the window.
Other than the use of the provided functions, the changing of any
characters in the calendar buffer by the hooks may cause the failure of the
functions that move by days and weeks.")
(defvar today-invisible-calendar-hook nil
"*List of functions called whenever the current date is not visible.
The corresponding variable today-visible-calendar-hook is the list of
functions called when the calendar function was called when the current
date is visible in the window.
Other than the use of the provided functions, the changing of any
characters in the calendar buffer by the hooks may cause the failure of the
functions that move by days and weeks.")
(defvar diary-file "~/diary"
"*Name of the file in which one's personal diary of dates is kept.
The file's entries are lines in the form DAY, MONTH/DAY or MONTH/DAY/YEAR
at the beginning of the line, followed by a nondigit; the remainder of the
line is the diary entry string for that date. MONTH and DAY are one or two
digit numbers, YEAR is a number and must be written in full. If the date
does not contain a year, it is generic and applies to any year; if it does
not contain a year or a month, it applies to any month.
Entries can also in the form MONTHNAME DAY or MONTHNAME DAY, YEAR or * DAY,
at the beginning of the line, where the month's name can be spelled in
full, abbreviated to three characters (with or without a period),
capitalized or not. If the date does not contain a year, it is generic and
applies to any year. The form * DAY is generic and applies to any month of
any year.
Entries can also be of the form DAYNAME at the beginning of a line,
followed by a nonletter. The day name can be spelled out in full (e.g.,
`Tuesday') or it can be abbreviated (e.g., `Tue'); it need not be
capitalized. DAYNAME entries apply to any date on which is on that day of
the week.
A diary entry can be preceded by a diary-nonmarking-symbol (ordinarily `&')
to make that entry nonmarking--that is, it will not be marked on dates in
the calendar window but will appear in a diary window.
Multiline diary entries are made by indenting lines after the first with
either a TAB or one or more spaces.
Lines not in one the above formats are ignored. Here are some sample diary
entries:
12/22/1988 Twentieth wedding anniversary!!
&1/1. Happy New Year!
10/22 Ruth's birthday.
21: Payday
Tuesday--weekly meeting with grad students at 10am
Supowit, Shen, Bitner, and Kapoor to attend.
1/13/1989 Friday the thirteenth!!
&thur 4pm squash game with Lloyd.
mar 16 Dad's birthday
April 15, 1989 Income tax due.
&* 15 time cards due.
")
(defvar diary-nonmarking-symbol "&"
"*The symbol used to indicate that a diary entry is not to be marked in the
calendar window.")
(defvar calendar-holidays
'((fixed 1 1 "New Year's Day")
(float 1 1 3 "Martin Luther King Day")
(fixed 2 2 "Ground Hog Day")
(fixed 2 14 "Valentine's Day")
(float 2 1 3 "President's Day")
(fixed 3 17 "St. Patrick's Day")
(special calendar-easter-etc)
(fixed 4 1 "April Fool's Day")
(hebrew 1 15 "Passover")
(float 4 0 1 "Beginning of Daylight Savings Time")
(float 5 0 2 "Mother's Day")
(float 5 1 5 "Memorial Day")
(hebrew 3 6 "Shavuoth")
(fixed 6 14 "Flag Day")
(float 6 0 3 "Father's Day")
(fixed 7 4 "Independence Day")
(float 9 1 1 "Labor Day")
(special calendar-rosh-hashanah-etc)
(float 10 1 2 "Columbus Day")
(float 10 0 5 "End of Daylight Savings Time")
(fixed 10 31 "Halloween")
(fixed 11 11 "Veteran's Day")
(float 11 4 4 "Thanksgiving")
(hebrew 9 25 "Hanukah")
(fixed 12 25 "Christmas")
(islamic 1 1 "Islamic New Year")
(islamic 9 1 "Ramadan Begins"))
"List of notable days for the command holidays.")
(defconst calendar-buffer "*Calendar*"
"Name of the buffer used for the calendar.")
(defconst holiday-buffer "*Holidays*"
"Name of the buffer used for the displayed diary entries.")
(defmacro increment-calendar-month (mon yr n)
"Move the variables MON and YR to the month and year N months forward
if N is positive or backward if N is negative."
(` (let (( macro-y (+ (* (, yr) 12) (, mon) -1 (, n) )))
(setq (, mon) (1+ (% macro-y 12) ))
(setq (, yr) (/ macro-y 12)))))
(defmacro calendar-for-loop (var from init to final do &rest body)
"Execute a for loop."
(` (let (( (, var) (1- (, init)) ))
(while (>= (, final) (setq (, var) (1+ (, var))))
(,@ body)))))
(defun calendar (&optional arg)
"Display a three-month calendar in another window.
The three months appear side by side, with the current month in the middle
surrounded by the previous and next months. The cursor is put on today's date.
This function is suitable for execution in a .emacs file; appropriate setting
of the variable view-diary-entries-initially will cause the diary entries for
the current date to be displayed in another window. The value of the variable
number-of-diary-entries controls the number of days of diary entries displayed.
An optional prefix argument ARG causes the calendar displayed to be ARG
months in the future if ARG is positive or in the past if ARG is negative;
in this case the cursor goes on the first day of the month.
Once in the calendar window, future or past months can be moved into view.
Arbitrary months can be displayed, or the calendar can be scrolled forward
or backward.
The cursor can be moved forward or backward by one day, one week, one month,
or one year. All of these commands take prefix arguments which, when negative,
cause movement in the opposite direction. For convenience, the digit keys
and the minus sign are automatically prefixes. The window is replotted as
necessary to display the desired date.
Diary entries can be marked on the calendar or displayed in another window.
Use describe-mode for details of the key bindings in the calendar window.
The Gregorian calendar is assumed.
After preparing the calendar window initially, the hooks
initial-calendar-window-hook are run.
The hooks today-visible-calendar-hook are run everytime the calendar window
gets shifted, if the current date is visible in the window. If it is not
visible, the hooks today-invisible-calendar-hook are run. Thus, for
example, setting today-visible-calendar-hook to 'calendar-star-date will
cause today's date to be replaced by asterisks to highlight it whenever it
is in the window."
(interactive "P")
(setq calendar-window-configuration (current-window-configuration))
(setq arg (if arg (prefix-numeric-value arg) 0))
(regenerate-calendar-window arg)
(let ((date (list current-month current-day current-year)))
(if (and view-diary-entries-initially (calendar-date-is-visible-p date))
(view-diary-entries
(if (vectorp number-of-diary-entries)
(aref number-of-diary-entries (calendar-day-of-week date))
number-of-diary-entries)))
(if view-calendar-holidays-initially
(list-calendar-holidays)))
(run-hooks 'initial-calendar-window-hook))
(defun diary ()
"Generate the diary window for the current date.
The number of days of diary entries is governed by number-of-diary-entries.
This function is suitable for execution in a .emacs file."
(interactive)
(if (and diary-file (file-exists-p diary-file))
(save-excursion
(let* ((date (calendar-current-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(day-in-week (calendar-day-of-week date))
(number-of-days (if (vectorp number-of-diary-entries)
(aref number-of-diary-entries day-in-week)
number-of-diary-entries)))
(if (< 0 number-of-days)
(list-diary-entries date number-of-days))))
(error "You don't have a diary file!")))
(defun holidays ()
"Display the holidays for last month, this month, and next month.
This function is suitable for execution in a .emacs file."
(interactive)
(save-excursion
(let* ((date (calendar-current-date))
(displayed-month (extract-calendar-month date))
(displayed-year (extract-calendar-year date)))
(list-calendar-holidays))))
(defun regenerate-calendar-window (&optional arg)
"Generate the calendar window, offset from the current date by ARG months."
(if (not arg) (setq arg 0))
(save-excursion
(set-buffer (get-buffer-create calendar-buffer))
(calendar-mode)
(let* ((buffer-read-only nil)
(date (calendar-current-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(day-in-week (calendar-day-of-week date))
(date-string
(concat (substring (calendar-day-name date) 0 3) ", "
(substring (calendar-month-name month) 0 3) " "
(int-to-string day) ", "
(int-to-string year))))
(setq mode-line-format
(format
"C-X < Calendar ? help/o other/c current %17s C-X >"
date-string))
(setq current-month month)
(setq current-day day)
(setq current-year year)
(increment-calendar-month month year arg)
(generate-calendar month year)))
(pop-to-buffer calendar-buffer)
(if mark-holidays-in-calendar
(mark-calendar-holidays))
(if mark-diary-entries-in-calendar
(mark-diary-entries))
(set-buffer-modified-p nil)
(or (one-window-p t)
(shrink-window (- (window-height) 9)))
(if (and (<= arg 1) (>= arg -1))
(progn;; When the current date is on the screen.
(calendar-cursor-to-visible-date
(list current-month current-day current-year))
(run-hooks 'today-visible-calendar-hook))
(progn;; When the current date is not on the screen.
(goto-char (point-min))
(run-hooks 'today-invisible-calendar-hook))))
(defun generate-calendar (month year)
"Generate a three-month Gregorian calendar centered around MONTH, YEAR."
(if (< (+ month (* 12 (1- year))) 2)
(error "Months before February, 1 AD are not available."))
(setq displayed-month month)
(setq displayed-year year)
(erase-buffer)
(increment-calendar-month month year -1)
(calendar-for-loop i from 0 to 2 do
(generate-calendar-month month year (+ 5 (* 25 i)))
(increment-calendar-month month year 1)))
(defun generate-calendar-month (month year indent)
"Produce a calendar for MONTH, YEAR on the Gregorian calendar.
The calendar is inserted in the buffer starting at the line on which point
is currently located, but indented INDENT spaces. The indentation is done
from the first character on the line and does not disturb the first INDENT
characters on the line."
(let* ((first-day-of-month (calendar-day-of-week (list month 1 year)))
(first-saturday (- 7 first-day-of-month))
(last (calendar-last-day-of-month month year)))
(goto-char (point-min))
(calendar-insert-indented
(format " %s %d" (calendar-month-name month) year) indent t)
(calendar-insert-indented " S M Tu W Th F S" indent t)
(calendar-insert-indented "" indent);; Move to appropriate spot on line
;; Add blank days before the first of the month
(calendar-for-loop i from 1 to first-day-of-month do
(insert " "))
;; Put in the days of the month
(calendar-for-loop i from 1 to last do
(insert (format "%2d " i))
(and (= (% i 7) (% first-saturday 7))
(/= i last)
(calendar-insert-indented "" 0 t) ;; Force onto following line
(calendar-insert-indented "" indent)))));; Go to proper spot
(defun calendar-insert-indented (string indent &optional newline)
"Insert STRING at column INDENT.
If the optional parameter NEWLINE is true, leave point at start of next
line, inserting a newline if there was no next line; otherwise, leave point
after the inserted text. Value is always `t'."
;; Try to move to that column.
(move-to-column indent)
;; If line is too short, indent out to that column.
(if (< (current-column) indent)
(indent-to indent))
(insert string)
;; Advance to next line, if requested.
(if newline
(progn
(end-of-line)
(if (eobp)
(newline)
(forward-line 1))))
t)
(defvar calendar-mode-map nil)
(if calendar-mode-map
nil
(setq calendar-mode-map (make-sparse-keymap))
(calendar-for-loop i from 0 to 9 do
(define-key calendar-mode-map (int-to-string i) 'digit-argument))
(define-key calendar-mode-map "-" 'negative-argument)
(define-key calendar-mode-map ">" 'shift-calendar-right)
(define-key calendar-mode-map "v" 'shift-right-three-months)
(define-key calendar-mode-map "<" 'shift-calendar-left)
(define-key calendar-mode-map "" 'shift-left-three-months)
(define-key calendar-mode-map "" 'calendar-backward-day)
(define-key calendar-mode-map "" 'calendar-backward-week)
(define-key calendar-mode-map "[" 'calendar-backward-month)
(define-key calendar-mode-map "[" 'calendar-backward-year)
(define-key calendar-mode-map "" 'calendar-forward-day)
(define-key calendar-mode-map "" 'calendar-forward-week)
(define-key calendar-mode-map "]" 'calendar-forward-month)
(define-key calendar-mode-map "]" 'calendar-forward-year)
(define-key calendar-mode-map "" 'calendar-beginning-of-week)
(define-key calendar-mode-map "" 'calendar-end-of-week)
(define-key calendar-mode-map "a" 'calendar-beginning-of-month)
(define-key calendar-mode-map "e" 'calendar-end-of-month)
(define-key calendar-mode-map "<" 'calendar-beginning-of-year)
(define-key calendar-mode-map ">" 'calendar-end-of-year)
(define-key calendar-mode-map "c" 'calendar-current-month)
(define-key calendar-mode-map "o" 'calendar-other-month)
(define-key calendar-mode-map "q" 'exit-calendar)
(define-key calendar-mode-map "h" 'list-calendar-holidays)
(define-key calendar-mode-map "x" 'mark-calendar-holidays)
(define-key calendar-mode-map "u" 'calendar-unmark)
(define-key calendar-mode-map "m" 'mark-diary-entries)
(define-key calendar-mode-map "d" 'view-diary-entries)
(define-key calendar-mode-map "s" 'show-all-diary-entries)
(define-key calendar-mode-map "m" 'describe-mode)
(define-key calendar-mode-map "?" 'describe-mode))
;; Calendar mode is suitable only for specially formatted data.
(put 'calendar-mode 'mode-class 'special)
(defun calendar-mode ()
"A major mode for the sliding calendar window and diary.
The commands for cursor movement are:\\<calendar-mode-map>
\\[calendar-forward-day] one day forward \\[calendar-backward-day] one day backward
\\[calendar-forward-week] one week forward \\[calendar-backward-week] one week backward
\\[calendar-forward-month] one month forward \\[calendar-backward-month] one month backward
\\[calendar-forward-year] one year forward \\[calendar-backward-year] one year backward
\\[calendar-beginning-of-week] beginning of week \\[calendar-end-of-week] end of week
\\[calendar-beginning-of-month] beginning of month \\[calendar-end-of-month] end of month
\\[calendar-beginning-of-year] beginning of year \\[calendar-end-of-year] end of year
The commands for calendar movement are:
\\[shift-calendar-right] shift one month right \\[shift-calendar-left] shift one month left
\\[shift-right-three-months] shift 3 months right \\[shift-left-three-months] shift 3 months left
\\[calendar-current-month] display current date \\[calendar-other-month] display another date
Except for the last two, all of the above commands take prefix arguments
that multiply their affect. For convenience, the digit keys and the minus
sign are bound to digit-argument, so they need not be prefixed with ESC.
The following commands list notable days:
\\[mark-calendar-holidays] mark notable days \\[calendar-unmark] unmark dates
\\[list-calendar-holidays] display notable days
The function `holidays' causes the notable dates for the current month, and
the preceding and succeeding months, to be displayed, independently of the
calendar.
The following commands control the diary:
\\[mark-diary-entries] mark diary entries \\[calendar-unmark] unmark dates
\\[view-diary-entries] display diary entries \\[show-all-diary-entries] show all diary entries
Displaying the diary entries causes the dairy entries from diary-file (for
the date indicated by the cursor in the calendar window) to be displayed in
another window. This function takes an integer argument that specifies the
number of days of calendar entries to be displayed, starting with the date
indicated by the cursor.
The function `diary' causes the diary entries for the current date to be
displayed, independently of the calendar. The number of days of entries is
governed by number-of-diary-entries.
The format of the entries in the diary file is described in the
documentation string for the variable diary-file.
When diary entries are in view in the window, they can be edited. It is
important to keep in mind that the buffer displayed contains the entire
diary file, but with portions of it concealed from view. This means, for
instance, that the forward-char command can put the cursor at what appears
to be the end of the line, but what is in reality the middle of some
concealed line. BE CAREFUL WHEN EDITING THE DIARY ENTRIES: (Inserting
additional lines or adding/deleting characters in the middle of a visible
line will not cause problems; watch out for end-of-line, however--it may
put you at the end of a concealed line far from where the cursor appears to
be!) BEFORE EDITING THE DIARY IT IS BEST TO DISPLAY THE ENTIRE FILE WITH
show-all-diary-entries. BE SURE TO WRITE THE FILE BEFORE EXITING FROM THE
CALENDAR.
To exit from the calendar use
\\[exit-calendar] exit from calendar
The variable view-diary-entries-initially, whose default is nil, can be set
to to t cause diary entries for the current date will be displayed in
another window when the calendar is first displayed, if the current date is
visible. The variable number-of-diary-entries controls number of days of
diary entries that will be displayed. For example, if the default value 1
is used, then only the current day's diary entries will be displayed. If
the value 2 is used, both the current day's and the next day's entries will
be displayed. The value can also be a vector: If the value is [0 2 2 2 2 4 1]
then no diary entries will be displayed on Sunday, the current date's
and the next day's diary entries will be displayed Monday through Thursday,
Friday through Monday's entries will be displayed on Friday, while on
Saturday only that day's entries will be displayed.
The variable mark-diary-entries-in-calendar can be set to t to cause any
dates visible with calendar entries to be marked with the symbol
diary-entry-marker, normally a plus sign.
The variable initial-calendar-window-hook, whose default value is nil,
is list of functions to be called when the calendar window is first opened.
The functions invoked are called after the calendar window is opened, but
once opened is never called again. Leaving the calendar with the `q' command
and reentering it will cause these functions to be called again.
The variable today-visible-calendar-hook, whose default value is nil,
is the list of functions called after the calendar buffer has been prepared
with the calendar when the current date is visible in the window.
This can be used, for example, to replace today's date with asterisks; a
function calendar-star-date is included for this purpose:
(setq today-visible-calendar-hook 'calendar-star-date)
It could also be used to mark the current date with `*'; a function is also
provided for this:
(setq today-visible-calendar-hook 'calendar-mark-today)
The variable today-invisible-calendar-hook, whose default value is nil,
is the list of functions called after the calendar buffer has been prepared
with the calendar when the current date is not visible in the window.
The Gregorian calendar is assumed."
(kill-all-local-variables)
(setq major-mode 'calendar-mode)
(setq mode-name "Calendar")
(use-local-map calendar-mode-map)
(setq buffer-read-only t)
(setq indent-tabs-mode nil)
(make-local-variable 'mode-line-format)
(make-local-variable 'calendar-window-configuration);; Windows on entry.
(make-local-variable 'current-month) ;; Current month.
(make-local-variable 'current-day) ;; Current day.
(make-local-variable 'current-year) ;; Current year.
(make-local-variable 'displayed-month);; Month in middle of window.
(make-local-variable 'displayed-year));; Year in middle of window.
(defun exit-calendar ()
"Get out of the calendar window and destroy it and related buffers."
(interactive)
(let ((diary-buffer (get-file-buffer diary-file)))
(if (not diary-buffer)
(progn
(kill-buffer calendar-buffer)
(kill-buffer (get-buffer holiday-buffer))
(set-window-configuration calendar-window-configuration))
(if (or (not (buffer-modified-p diary-buffer))
(yes-or-no-p "Diary modified; do you really want to exit the calendar? "))
(progn
(kill-buffer calendar-buffer)
(kill-buffer (get-buffer holiday-buffer))
(set-buffer diary-buffer)
(set-buffer-modified-p nil)
(kill-buffer diary-buffer)
(set-window-configuration calendar-window-configuration))))))
(defun calendar-current-month ()
"Reposition the calendar window so the current date is visible."
(interactive)
(let ((date (calendar-current-date)));; The date might have changed.
(setq current-month (extract-calendar-month date))
(setq current-day (extract-calendar-day date))
(setq current-year (extract-calendar-year date))
(if (calendar-date-is-visible-p date)
(calendar-cursor-to-visible-date date)
(regenerate-calendar-window))))
(defun calendar-forward-month (arg)
"Move the cursor forward ARG months.
Movement is backward if ARG is negative."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let*
((cursor-date (or (calendar-cursor-to-date)
(error "Cursor is not on a date!")))
(month (extract-calendar-month cursor-date))
(day (extract-calendar-day cursor-date))
(year (extract-calendar-year cursor-date)))
(increment-calendar-month month year arg)
(let ((last (calendar-last-day-of-month month year)))
(if (< last day)
(setq day last)))
;; Put the new month on the screen, if needed, and go to the new date.
(let ((new-cursor-date (list month day year)))
(if (not (calendar-date-is-visible-p new-cursor-date))
(calendar-other-month month year))
(calendar-cursor-to-visible-date new-cursor-date))))
(defun calendar-forward-year (arg)
"Move the cursor forward by ARG years.
Movement is backward if ARG is negative."
(interactive "p")
(calendar-forward-month (* 12 arg)))
(defun calendar-backward-month (arg)
"Move the cursor backward by ARG months.
Movement is forward if ARG is negative."
(interactive "p")
(calendar-forward-month (- arg)))
(defun calendar-backward-year (arg)
"Move the cursor backward ARG years.
Movement is forward is ARG is negative."
(interactive "p")
(calendar-forward-month (* -12 arg)))
(defun shift-calendar-left (arg)
"Shift the displayed calendar left by ARG months.
If ARG is negative the calendar is shifted right. The relative position of
the cursor with respect to the calendar is maintained as well as possible."
(interactive "p")
(let* ((old-date (calendar-cursor-to-date)))
(if (/= arg 0)
(progn
(regenerate-calendar-window
(+ arg (calendar-interval current-month current-year
displayed-month displayed-year)))
(if (calendar-date-is-visible-p old-date)
(calendar-cursor-to-visible-date old-date)
(calendar-cursor-to-visible-date
(list displayed-month 1 displayed-year)))))))
(defun shift-calendar-right (arg)
"Shift the displayed calendar window right by ARG months.
If ARG is negative the calendar is shifted left. The relative position of
the cursor with respect to the calendar is maintained as well as possible."
(interactive "p")
(shift-calendar-left (- arg)))
(defun shift-left-three-months (arg)
"Shift the displayed calendar window left by 3*ARG months.
If ARG is negative the calendar is shifted right. The relative position of
the cursor with respect to the calendar is maintained as well as possible."
(interactive "p")
(shift-calendar-left (* 3 arg)))
(defun shift-right-three-months (arg)
"Shift the displayed calendar window right by 3*ARG months.
If ARG is negative the calendar is shifted left. The relative position of
the cursor with respect to the calendar is maintained as well as possible."
(interactive "p")
(shift-calendar-left (* -3 arg)))
(defun calendar-current-date ()
"Returns the current date in a list (month day year)."
(let* ((date (current-time-string))
(garbage
(string-match
"^\\([A-Z][a-z]*\\) *\\([A-Z][a-z]*\\) *\\([0-9]*\\) .* \\([0-9]*\\)$"
date))
(month
(cdr (assoc
(substring date (match-beginning 2) (match-end 2))
calendar-month-abbrev-list)))
(day
(string-to-int (substring date (match-beginning 3) (match-end 3))))
(year
(string-to-int (substring date (match-beginning 4) (match-end 4)))))
(list month day year)))
(defun calendar-cursor-to-date ()
"Returns a list of the month, day, and year of current cursor position.
NIL if the cursor is not on a specific day."
(if (and (looking-at "[*0-9]")
(< 2 (count-lines (point-min) (point))))
(save-excursion
(re-search-backward "[^0-9]")
(forward-char 1)
(let*
((day (string-to-int (buffer-substring (point) (+ 3 (point)))))
(day (if (= 0 day) current-day day));; Starred date.
(segment (/ (current-column) 25))
(month (% (+ displayed-month segment -1) 12))
(month (if (= 0 month) 12 month))
(year
(cond
((and (= 12 month) (= segment 0)) (1- displayed-year))
((and (= 1 month) (= segment 2)) (1+ displayed-year))
(t displayed-year))))
(list month day year)))))
(defun calendar-cursor-to-nearest-date ()
"Move the cursor to the closest date.
The position of the cursor is unchanged if it is already on a date.
The value returned is the list (month day year) of the cursor position."
(let ((date (calendar-cursor-to-date))
(column (current-column)))
(if date
date
(if (> 3 (count-lines (point-min) (point)))
(progn
(goto-line 3)
(move-to-column column)))
(if (not (looking-at "[0-9]"))
(if (and (not (looking-at " *$"))
(or (< column 25)
(and (> column 27)
(< column 50))
(and (> column 52)
(< column 75))))
(progn
(re-search-forward "[0-9]" nil t)
(backward-char 1))
(re-search-backward "[0-9]" nil t)))
(calendar-cursor-to-date))))
(defun calendar-forward-day (arg)
"Move the cursor forward ARG days.
Movement is backward if ARG is negative."
(interactive "p")
(if (/= 0 arg)
(let*
((cursor-date (calendar-cursor-to-date))
(cursor-date (if cursor-date
cursor-date
(setq arg (if (< arg 0) (1+ arg) (1- arg)))
(calendar-cursor-to-nearest-date)))
(new-cursor-date
(calendar-gregorian-from-absolute
(+ (calendar-absolute-from-gregorian cursor-date) arg)))
(new-display-month (extract-calendar-month new-cursor-date))
(new-display-year (extract-calendar-year new-cursor-date)))
;; Put the new month on the screen, if needed, and go to the new date.
(if (not (calendar-date-is-visible-p new-cursor-date))
(calendar-other-month new-display-month new-display-year))
(calendar-cursor-to-visible-date new-cursor-date))))
(defun calendar-backward-day (arg)
"Move the cursor back ARG days.
Movement is forward if ARG is negative."
(interactive "p")
(calendar-forward-day (- arg)))
(defun calendar-forward-week (arg)
"Move the cursor forward ARG weeks.
Movement is backward if ARG is negative."
(interactive "p")
(calendar-forward-day (* arg 7)))
(defun calendar-backward-week (arg)
"Move the cursor back ARG weeks.
Movement is forward if ARG is negative."
(interactive "p")
(calendar-forward-day (* arg -7)))
(defun calendar-beginning-of-week (arg)
"Move the cursor back ARG Sundays."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let ((day (calendar-day-of-week (calendar-cursor-to-date))))
(calendar-backward-day
(if (= day 0) (* 7 arg) (+ day (* 7 (1- arg)))))))
(defun calendar-end-of-week (arg)
"Move the cursor forward ARG Saturdays."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let ((day (calendar-day-of-week (calendar-cursor-to-date))))
(calendar-forward-day
(if (= day 6) (* 7 arg) (+ (- 6 day) (* 7 (1- arg)))))))
(defun calendar-beginning-of-month (arg)
"Move the cursor backward ARG month beginnings."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let* ((date (calendar-cursor-to-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date)))
(if (= day 1)
(calendar-backward-month arg)
(calendar-cursor-to-visible-date (list month 1 year))
(calendar-backward-month (1- arg)))))
(defun calendar-end-of-month (arg)
"Move the cursor forward ARG month ends."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let* ((date (calendar-cursor-to-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(last-day (calendar-last-day-of-month month year)))
(if (/= day last-day)
(progn
(calendar-cursor-to-visible-date (list month last-day year))
(setq arg (1- arg))))
(increment-calendar-month month year arg)
(let ((last-day (list
month
(calendar-last-day-of-month month year)
year)))
(if (not (calendar-date-is-visible-p last-day))
(calendar-other-month month year)
(calendar-cursor-to-visible-date last-day)))))
(defun calendar-beginning-of-year (arg)
"Move the cursor backward ARG year beginnings."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let* ((date (calendar-cursor-to-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(jan-first (list 1 1 year)))
(if (and (= day 1) (= 1 month))
(calendar-backward-month (* 12 arg))
(if (and (= arg 1)
(calendar-date-is-visible-p jan-first))
(calendar-cursor-to-visible-date jan-first)
(calendar-other-month 1 (- year (1- arg)))))))
(defun calendar-end-of-year (arg)
"Move the cursor forward ARG year beginnings."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let* ((date (calendar-cursor-to-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(year (extract-calendar-year date))
(dec-31 (list 12 31 year)))
(if (and (= day 31) (= 12 month))
(calendar-forward-month (* 12 arg))
(if (and (= arg 1)
(calendar-date-is-visible-p dec-31))
(calendar-cursor-to-visible-date dec-31)
(calendar-other-month 12 (- year (1- arg)))
(calendar-cursor-to-visible-date (list 12 31 displayed-year))))))
(defun extract-calendar-month (date)
"Extract the month part of DATE which has the form (month day year)."
(car date))
(defun extract-calendar-day (date)
"Extract the day part of DATE which has the form (month day year)."
(car (cdr date)))
(defun extract-calendar-year (date)
"Extract the year part of DATE which has the form (month day year)."
(car (cdr (cdr date))))
(defun calendar-gregorian-from-absolute (date)
"Compute the list (month day year) corresponding to the absolute DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let ((month 1)
(day 0)
(year (/ date 366)))
;; Calculate month, day, and year of DATE.
(while (< (calendar-absolute-from-gregorian (list 12 31 year)) date)
(setq year (1+ year)))
(while (< (calendar-absolute-from-gregorian
(list month (calendar-last-day-of-month month year) year))
date)
(setq month (1+ month)))
(setq day
(- (1+ date)
(calendar-absolute-from-gregorian (list month 1 year))))
(list month day year)))
(defun calendar-cursor-to-visible-date (date)
"Move the cursor to DATE that is on the screen."
(let ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date)))
(goto-line (+ 3
(/ (+ day -1
(calendar-day-of-week (list month 1 year)))
7)))
(move-to-column (+ 6
(* 25
(1+ (calendar-interval
displayed-month displayed-year month year)))
(* 3 (calendar-day-of-week date))))))
(defun calendar-other-month (month year)
"Display a three-month calendar centered around MONTH and YEAR."
(interactive "nMonth (1-12): \nnYear (>0): ")
(if (or (< 12 month) (> 1 month) (> 1 year))
(error "Unacceptable month/year!"))
(if (and (= month displayed-month)
(= year displayed-year))
nil
(regenerate-calendar-window
(calendar-interval current-month current-year month year))
(calendar-cursor-to-visible-date (list month 1 year))))
(defun calendar-interval (mon1 yr1 mon2 yr2)
"The number of months difference between the two specified months."
(+ (* 12 (- yr2 yr1))
(- mon2 mon1)))
(defun calendar-leap-year-p (year)
"Returns true if YEAR is a Gregorian leap year, and false if not."
(or
(and (= (% year 4) 0)
(/= (% year 100) 0))
(= (% year 400) 0)))
(defun calendar-day-number (date)
"Return the day number within the year of the date DATE.
For example, (calendar-day-number (1 1 1987)) returns the value 1,
while (calendar-day-number (12 31 1980)) returns 366."
;;
;; An explanation of the calculation can be found in PascAlgorithms by
;; Edward and Ruth Reingold, Scott-Foresman/Little, Brown, 1988.
;;
(let* ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(day-of-year (+ day (* 31 (1- month)))))
(if (> month 2)
(progn
(setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
(if (calendar-leap-year-p year)
(setq day-of-year (1+ day-of-year)))))
day-of-year))
(defun calendar-day-name (date)
"Returns a string with the name of the day of the week of DATE."
(aref
["Sunday" "Monday" "Tuesday" "Wednesday" "Thursday" "Friday" "Saturday"]
(calendar-day-of-week date)))
(defconst calendar-month-abbrev-list
'(("Jan" . 1) ("Feb" . 2) ("Mar" . 3) ("Apr" . 4)
("May" . 5) ("Jun" . 6) ("Jul" . 7) ("Aug" . 8)
("Sep" . 9) ("Oct" . 10) ("Nov" . 11) ("Dec" . 12)))
(defun calendar-day-of-week (date)
"Returns the day-of-the-week index of DATE, 0 for Sunday, 1 for Monday, etc."
(% (calendar-absolute-from-gregorian date) 7))
(defun calendar-absolute-from-gregorian (date)
"The number of days elapsed between the Gregorian date 12/31/1 BC and DATE.
The Gregorian date Sunday, December 31, 1 BC is imaginary."
(let ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date)))
(-
(+ (calendar-day-number date)
(* 365 (1- year))
(/ (1- year) 4))
(let ((correction (* (/ (1- year) 100) 3)))
(if (= (% correction 4) 0)
(/ correction 4)
(1+ (/ correction 4)))))))
(defun calendar-last-day-of-month (month year)
"The last day in MONTH during YEAR."
(if (and (calendar-leap-year-p year) (= month 2))
29
(aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
(defun calendar-month-name (month)
"The name of MONTH."
(aref ["January" "February" "March" "April" "May" "June"
"July" "August" "September" "October" "November" "December"]
(1- month)))
(defun view-diary-entries (arg)
"Prepare and display a buffer with diary entries.
Searches the file diary-file for entries that match ARG days starting with
the date indicated by the cursor position in the displayed three-month
calendar."
(interactive "p")
(if (and diary-file (file-exists-p diary-file))
(if (< 0 arg)
(let ((cursor-date (or (calendar-cursor-to-date)
(error "Cursor is not on a date!"))))
(list-diary-entries cursor-date arg)))
(error "You don't have a diary file!")))
(defun list-diary-entries (date number)
"Create a buffer containing the relevant lines in diary-file.
All lines that apply to DATE and the next NUMBER-1 days are included."
(let* ((any-entries)
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(date-string
(format "%s, %s %d, %d"
(calendar-day-name date)
(calendar-month-name month)
day
year)))
(save-excursion
(let ((diary-buffer (get-file-buffer diary-file)))
(set-buffer (if diary-buffer
diary-buffer
(find-file-noselect diary-file t))))
(setq selective-display t)
(setq selective-display-ellipses nil)
(make-local-variable 'mode-line-format)
(setq mode-line-format
(concat "%*-----------------Diary entries for " date-string "%-"))
(let ((diary-modified (buffer-modified-p)))
(goto-char (point-max))
(if (not (looking-at "\^M\\|\n"))
(progn
(insert-string "\^M")
(set-buffer-modified-p diary-modified)))
(goto-char (point-min))
(if (not (looking-at "\^M\\|\n"))
(progn
(insert-string "\^M")
(set-buffer-modified-p diary-modified)))
(subst-char-in-region (point-min) (point-max) ?\n ?\^M t)
(calendar-for-loop i from 1 to number do
(goto-char (point-min))
(let ((regexp
(concat
"\\(\\`\\|\^M\\)\\("
"\\(\" diary-nonmarking-symbol "?"
(int-to-string day) "[^0-9/]\\)"
"\\|\\(\" diary-nonmarking-symbol "?" (int-to-string month)
"/" (int-to-string day) "[^0-9/]\\)"
"\\|\\(\" diary-nonmarking-symbol "?" (int-to-string month)
"/" (int-to-string day)
"/" (int-to-string year) "[^0-9/]\\)"
"\\|\\(\" diary-nonmarking-symbol "?"
(substring (calendar-month-name month) 0 3)
"\\(" (substring (calendar-month-name month) 3 nil)
"\\|\\.?\\) +" (int-to-string day)
"\\(," (int-to-string year) "\\)?\\)"
"\\|\\(\" diary-nonmarking-symbol "?\\* +"
(int-to-string day) "\\)"
"\\|\" diary-nonmarking-symbol "?"
(substring (calendar-day-name date) 0 3)
"\\)"))
(case-fold-search t))
(while (re-search-forward regexp nil t)
(setq any-entries t)
(re-search-backward "\^M\\|\\`")
(let ((start (point)))
(re-search-forward "\^M" nil t 2)
(while (looking-at " \\| ")
(re-search-forward "\^M" nil t))
(backward-char 1)
(subst-char-in-region start (point) ?\^M ?\n t)))
(setq date
(calendar-gregorian-from-absolute
(1+ (calendar-absolute-from-gregorian date))))
(setq month (extract-calendar-month date))
(setq day (extract-calendar-day date))
(setq year (extract-calendar-year date))))
(if (not any-entries)
(message "No diary entries for %s" date-string ".")
(goto-char (point-min))
(display-buffer (current-buffer)))
(set-buffer-modified-p diary-modified)))))
(defun show-all-diary-entries ()
"Show all of the diary entries in the diary-file.
This function gets rid of the selective display of the diary-file so that
all entries, not just some, are visible. If there is no diary buffer, one
is created."
(interactive)
(if (and diary-file (file-exists-p diary-file))
(save-excursion
(let ((diary-buffer (get-file-buffer diary-file)))
(set-buffer (if diary-buffer
diary-buffer
(find-file-noselect diary-file t)))
(let ((diary-modified (buffer-modified-p)))
(subst-char-in-region (point-min) (point-max) ?\^M ?\n t)
(setq selective-display nil)
(make-local-variable 'mode-line-format)
(setq mode-line-format
(concat "%*---------------------------All Diary Entries%-"))
(display-buffer (current-buffer))
(set-buffer-modified-p diary-modified))))
(error "You don't have a diary file!")))
(defun mark-diary-entries ()
"Mark days in the calendar window that have diary entries.
Each entry in diary-file visible in the calendar window, is marked."
(interactive)
(if (and diary-file (file-exists-p diary-file))
(save-excursion
(message "Marking diary entries...")
(set-buffer (find-file-noselect diary-file t))
;; For each marking DAYNAME entry in the diary-file,
;; mark dates with that name.
(let ((case-fold-search t))
(calendar-for-loop day from 0 to 6 do
(goto-char (point-min))
(if (re-search-forward
(concat "\\(^\\|\^M\\)"
(aref ["Sun" "Mon" "Tue" "Wed" "Thu" "Fri" "Sat"]
day))
nil t)
(mark-calendar-days-named day)))
;; For each marking entry in the diary-file,
;; mark it if it is in range.
(goto-char (point-min))
(while
(re-search-forward "\\(^\\|\^M\\)\\([0-9]+\\|[*.a-z]+\\)[^0-9]"
nil t)
(let ((month (buffer-substring (match-beginning 2)
(match-end 2)))
(named-month t)
(day 0)
(year 0))
(if (string-equal "*" (substring month 0 1))
(setq month 0)
(let ((value (string-to-int month)))
(if (= value 0)
(setq month
(cdr (assoc
(capitalize (substring month 0 3))
calendar-month-abbrev-list)))
(setq month value)
(setq named-month nil))))
(if month;; Not nil means it was found.
(progn
(backward-char 1)
(if (or named-month (looking-at "/"))
(progn
(re-search-forward
"\\( \\|/\\)\\([0-9]+\\)[^0-9]" nil t)
(setq day (string-to-int
(buffer-substring (match-beginning 2)
(match-end 2)))))
(setq day month);; It's a DAY entry, not a MONTH.
(setq month 0)
(forward-char 1))
(backward-char 1)
(if (or (looking-at "/")
(and named-month (looking-at ",")))
(progn
(re-search-forward
"\\(, +\\|/\\)\\([0-9]+\\)[^0-9]" nil t)
(setq year (string-to-int
(buffer-substring (match-beginning 2)
(match-end 2))))))
(mark-calendar-date-pattern month day year))))))
(message "Marking diary entries...done"))
(error "You don't have a diary file!")))
(defun mark-calendar-days-named (dayname)
"Mark all dates in the calendar window that are day DAYNAME of the week.
0 means all Sundays, 1 means all Mondays, and so on."
(save-excursion
(set-buffer calendar-buffer)
(let ((prev-month displayed-month)
(prev-year displayed-year)
(succ-month displayed-month)
(succ-year displayed-year)
(last-day)
(day))
(increment-calendar-month succ-month succ-year 1)
(increment-calendar-month prev-month prev-year -1)
(setq day (calendar-absolute-from-gregorian
(calendar-nth-named-day dayname 1 prev-month prev-year)))
(setq last-day (calendar-absolute-from-gregorian
(calendar-nth-named-day dayname 5 succ-month succ-year)))
(while (<= day last-day)
(mark-visible-calendar-date (calendar-gregorian-from-absolute day))
(setq day (+ day 7))))))
(defun mark-calendar-date-pattern (month day year)
"Mark all dates in the calendar window that conform to MONTH/DAY/YEAR.
A value of 0 is a wild-card. Either only the year is 0 or both the month
and the year are 0; the month alone cannot be 0."
(save-excursion
(set-buffer calendar-buffer)
(let ((prev-month displayed-month)
(prev-year displayed-year)
(succ-month displayed-month)
(succ-year displayed-year))
(increment-calendar-month succ-month succ-year 1)
(increment-calendar-month prev-month prev-year -1)
(if (or (and (= month prev-month)
(or (= year 0) (= year prev-year)))
(= month 0))
(mark-visible-calendar-date (list prev-month day prev-year)))
(if (or (and (= month displayed-month)
(or (= year 0) (= year displayed-year)))
(= month 0))
(mark-visible-calendar-date
(list displayed-month day displayed-year)))
(if (or (and (= month succ-month)
(or (= year 0) (= year succ-year)))
(= month 0))
(mark-visible-calendar-date (list succ-month day succ-year))))))
(defun calendar-unmark ()
"Delete the diary and holiday marks from the calendar."
(interactive)
(let ((position (point))
(buffer-read-only nil))
(goto-char (point-min))
(forward-line 2)
(while (re-search-forward
(concat diary-entry-marker "\\|" calendar-holiday-marker)
nil t)
(delete-char -1)
(insert " "))
(goto-char position)
(set-buffer-modified-p nil)))
(defun calendar-date-is-visible-p (date)
"Returns true if DATE is legal and is visible in the calendar window."
(save-excursion
(if (bufferp calendar-buffer) (set-buffer calendar-buffer))
(let ((gap (calendar-interval
displayed-month displayed-year
(extract-calendar-month date) (extract-calendar-year date))))
(and (calendar-date-is-legal-p date) (> 2 gap) (< -2 gap)))))
(defun calendar-date-is-legal-p (date)
"Returns true if DATE is a legal date."
(let ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date)))
(and (<= 1 month) (<= month 12)
(<= 1 day) (<= day (calendar-last-day-of-month month year))
(<= 1 year))))
(defun mark-visible-calendar-date (date &optional mark)
"Leave mark DATE with MARK. MARK defaults to diary-entry-marker."
(if (calendar-date-is-legal-p date)
(save-excursion
(set-buffer calendar-buffer)
(calendar-cursor-to-visible-date date)
(forward-char 1)
(let ((buffer-read-only nil))
(delete-char 1)
(insert (if mark mark diary-entry-marker))
(forward-char -2))
(set-buffer-modified-p nil))))
(defun calendar-nth-named-day (dayname n month year)
"Returns the date of the Nth DAYNAME in MONTH, YEAR.
A DAYNAME of 0 means Sunday, 1 means Monday, and so on. If N>4, the
date returned is the last DAYNAME in MONTH, YEAR."
(let* ((first-day-name (calendar-day-of-week (list month 1 year)))
(day (1+ (- dayname first-day-name))))
(if (<= day 0)
(setq day (+ day 7)))
;; Day is now the first DAYNAME in the month.
(setq day (+ day (* 7 (1- n))))
(while (> day (calendar-last-day-of-month month year))
(setq day (- day 7)))
(list month day year)))
(defun calendar-star-date ()
"Replace the date under the cursor in the calendar window with asterisks.
This function can be used with the today-visible-calendar-hook run after the
calendar window has been prepared."
(let ((buffer-read-only nil))
(forward-char 1)
(delete-char -2)
(insert "**")
(backward-char 1)
(set-buffer-modified-p nil)))
(defun calendar-mark-today ()
"Mark the date under the cursor in the calendar window with an asterisk.
This function can be used with the today-visible-calendar-hook run after the
calendar window has been prepared."
(let ((buffer-read-only nil))
(forward-char 1)
(delete-char 1)
(insert "*")
(backward-char 2)
(set-buffer-modified-p nil)))
(defun calendar-fixed-day (month day string)
"Returns the exact date, if visible in the window.
If it is visible, the value returned is the list ((MONTH DAY year) STRING).
NIL is returned if it is not visible in the current calendar window."
(let ((m displayed-month)
(y displayed-year))
(increment-calendar-month m y (- 11 month))
(if (> m 9)
(list (list month day y) string))))
(defun calendar-float-day (month dayname n string)
"Returns date of the n-th occurence of day named, if visible in the window.
If it is visible, a list is returned consisting of the date in MONTH of the
day DAYNAME's N-th appearance, followed by STRING. NIL is returned if it
is not visible in the current calendar window. If it is visible, the value
returned is ((MONTH day year) STRING), where (MONTH day year) is the N-th
DAYNAME of MONTH. If N>4, the last occurence is returned."
(let ((m displayed-month)
(y displayed-year))
(increment-calendar-month m y (- 11 month))
(if (> m 9)
(list (calendar-nth-named-day dayname n month y) string))))
(defun calendar-holiday-list ()
"Form the list of holidays that occur on dates in the calendar window.
The holidays are those in the list calendar-holidays."
(let ((p calendar-holidays)
(holiday)
(holiday-list))
(while p
(cond
((equal (car (car p)) 'fixed)
(setq holiday (calendar-fixed-day
(car (nthcdr 1 (car p)))
(car (nthcdr 2 (car p)))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'float)
(setq holiday (calendar-float-day
(car (nthcdr 1 (car p)))
(car (nthcdr 2 (car p)))
(car (nthcdr 3 (car p)))
(car (nthcdr 4 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'hebrew)
(setq holiday (hebrew-calendar-date
(car (nthcdr 1 (car p)))
(car (nthcdr 2 (car p)))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'islamic)
(setq holiday (islamic-calendar-date
(car (nthcdr 1 (car p)))
(car (nthcdr 2 (car p)))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'special)
(setq holiday (funcall (car (nthcdr 1 (car p)))))
(if holiday
(setq holiday-list (append holiday holiday-list)))))
(setq p (cdr p)))
(sort holiday-list 'calendar-list-compare)))
(defun mark-calendar-holidays ()
"Mark notable days in the calendar window."
(interactive)
(message "Marking holidays...")
(let ((holiday-list (calendar-holiday-list)))
(while holiday-list
(mark-visible-calendar-date
(car (car holiday-list)) calendar-holiday-marker)
(setq holiday-list (cdr holiday-list))))
(message "Marking holidays...done"))
(defun list-calendar-holidays ()
"Create a buffer containing the holidays for the current calendar window.
The holidays are those in the list calendar-notable-days."
(interactive)
(message "Looking up holidays...")
(let ((holiday-list (calendar-holiday-list))
(m1 displayed-month)
(y1 displayed-year)
(m2 displayed-month)
(y2 displayed-year))
(if (not holiday-list)
(message "Looking up holidays...none found")
(set-buffer (get-buffer-create "*Holidays*"))
(setq buffer-read-only nil)
(increment-calendar-month m1 y1 -1)
(increment-calendar-month m2 y2 1)
(setq mode-line-format
(concat "-------------Notable Dates from "
(calendar-month-name m1) ", "
(int-to-string y1) " to "
(calendar-month-name m2) ", "
(int-to-string y2)
"%-"))
(erase-buffer)
(while holiday-list
(insert-string (calendar-date-string (car (car holiday-list))))
(insert-string ": ")
(insert-string (car (cdr (car holiday-list))))
(insert-string "\n")
(setq holiday-list (cdr holiday-list)))
(set-buffer-modified-p nil)
(setq buffer-read-only t)
(display-buffer holiday-buffer)
(message "Looking up holidays...done"))))
(defun calendar-list-compare (date1 date2)
"T if DATE1 is before DATE2, NIL otherwise.
The actual dates are in the car of DATE1 and DATE2."
(< (calendar-absolute-from-gregorian (car date1))
(calendar-absolute-from-gregorian (car date2))))
(defun calendar-date-string (date)
"A string form of DATE."
(concat
(calendar-day-name date) ", "
(calendar-month-name (extract-calendar-month date)) " "
(int-to-string (extract-calendar-day date)) ", "
(int-to-string (extract-calendar-year date))))
(defun calendar-easter-etc ()
"List of dates related to Easter, as visible in calendar window.
The algorithm is from pages 155-156 of The Art of Computer Programming,
Volume 1, second edition, by Donald E. Knuth."
(if (> displayed-month 5)
nil;; Ash Wednesday, Good Friday, and Easter are not visible.
(let* ((c (1+ (/ displayed-year 100)));; century
(g (1+ (% displayed-year 19)));; golden number
(x (- (/ (* 3 c) 4) 12));; number of non-leap year century years
(z (- (/ (+ (* 8 c) 5) 25) 5));; lunar correction
(d (- (/ (* 5 displayed-year) 4) x 10));; sunday
(e (+ (* 11 g) 20 z (- x)));; epact (full moon)
(e (if (< e 0)
(% (+ e 30) 30)
(% e 30)))
(e (if (or (and (= e 25) (> g 11))
(= e 24))
(1+ e)
e))
(n (- 44 e));; n-th of March is a full moon.
(n (if (< n 21)
(+ n 30)
n))
(n (+ n 7 (- (% (+ d n) 7))));; the next Sunday
(easter
(if (> n 31)
(list 4 (- n 31) displayed-year)
(list 3 n displayed-year)))
(abs-easter (calendar-absolute-from-gregorian easter))
(good-friday (calendar-gregorian-from-absolute (- abs-easter 2)))
(ash-weds (calendar-gregorian-from-absolute (- abs-easter 46)))
(output-list))
(if (calendar-date-is-visible-p ash-weds)
(setq output-list (list (list ash-weds "Ash Wednesday"))))
(if (calendar-date-is-visible-p good-friday)
(setq output-list
(append (list (list good-friday "Good Friday")) output-list)))
(if (calendar-date-is-visible-p easter)
(setq output-list
(append (list (list easter "Easter")) output-list)))
output-list)))
(defun islamic-calendar-leap-year-p (year)
"Returns T if YEAR is a leap year on the Islamic calendar."
(memq (% year 30)
(list 2 5 7 10 13 16 18 21 24 26 29)))
(defun islamic-calendar-last-day-of-month (month year)
"The last day in MONTH during YEAR on the Islamic calendar."
(cond
((memq month (list 1 3 5 7 9 11)) 30)
((memq month (list 2 4 6 8 10)) 29)
(t (if (islamic-calendar-leap-year-p year) 30 29))))
(defun islamic-calendar-day-number (date)
"Return the day number within the year of the Islamic date DATE."
(let* ((month (extract-calendar-month date))
(day (extract-calendar-day date)))
(+ (* 30 (/ month 2))
(* 29 (/ (1- month) 2))
day)))
(defun calendar-absolute-from-islamic (date)
"Absolute date of Islamic DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let* ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(y (% year 30))
(leap-years-in-cycle
(cond
((< y 3) 0) ((< y 6) 1) ((< y 8) 2) ((< y 11) 3) ((< y 14) 4)
((< y 17) 5) ((< y 19) 6) ((< y 22) 7) ((< y 25) 8) ((< y 27) 9)
(t 10))))
(+ (islamic-calendar-day-number date);; days so far this year
(* (1- year) 354) ;; days in all non-leap years
(* 11 (/ year 30)) ;; leap days in complete cycles
leap-years-in-cycle ;; leap days this cycle
227014))) ;; days before start of calendar
(defun calendar-islamic-from-absolute (date)
"Compute the Islamic date (month day year) corresponding to absolute DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let* ((month 1)
(day 1)
(year (/ (- date 227014) 355)))
(if (< year 0)
(list 0 0 0)
(while (> date
(calendar-absolute-from-islamic
(list 12 (islamic-calendar-last-day-of-month 12 year) year)))
(setq year (1+ year)))
(while (> date
(calendar-absolute-from-islamic
(list month
(islamic-calendar-last-day-of-month month year)
year)))
(setq month (1+ month)))
(setq day
(1+ (- date (calendar-absolute-from-islamic (list month 1 year)))))
(list month day year))))
(defun islamic-calendar-date (month day string)
"Returns the corresponding Gregorian date, if visible in the window.
If it is visible, the value returned is the list ((MONTH DAY year) STRING).
NIL is returned if it is not visible in the current calendar window."
(let* ((islamic-date (calendar-islamic-from-absolute
(calendar-absolute-from-gregorian
(list displayed-month 15 displayed-year))))
(m (extract-calendar-month islamic-date))
(y (extract-calendar-year islamic-date))
(date))
(if (< m 1)
nil;; Islamic calendar doesn't apply.
(increment-calendar-month m y (- 10 month))
(if (> m 7);; (MONTH, DAY, y) might be visible
(let ((date (calendar-gregorian-from-absolute
(calendar-absolute-from-islamic (list month day y)))))
(if (calendar-date-is-visible-p date)
(list date string)))))))
(defun calendar-rosh-hashanah-etc ()
"List of dates related to Rosh Hashanah, as visible in calendar window."
(if (or (< displayed-month 8)
(> displayed-month 11))
nil;; None of the dates are visible
(let* ((abs-r-h (hebrew-calendar-new-year-day displayed-year))
(rosh-h (calendar-gregorian-from-absolute abs-r-h))
(yom-k (calendar-gregorian-from-absolute (+ abs-r-h 9)))
(suc (calendar-gregorian-from-absolute (+ abs-r-h 14)))
(output-list))
(if (calendar-date-is-visible-p rosh-h)
(setq output-list (list (list rosh-h "Rosh Hashanah"))))
(if (calendar-date-is-visible-p yom-k)
(setq output-list
(append (list (list yom-k "Yom Kippur")) output-list)))
(if (calendar-date-is-visible-p suc)
(setq output-list
(append (list (list suc "Succoth")) output-list)))
output-list)))
(defun hebrew-calendar-date (month day string)
"Returns the corresponding Gregorian date, if visible in the window.
If it is visible, the value returned is the list ((MONTH DAY year) STRING).
NIL is returned if it is not visible in the current calendar window."
(if (memq displayed-month;; This test is only to speed things up a bit;
(list ;; it works fine without the test too.
(if (< 11 month) (- month 11) (+ month 1))
(if (< 10 month) (- month 10) (+ month 2))
(if (< 9 month) (- month 9) (+ month 3))
(if (< 8 month) (- month 8) (+ month 4))))
(let* ((hebrew-date (calendar-hebrew-from-absolute
(calendar-absolute-from-gregorian
(list displayed-month 15 displayed-year))))
(m (extract-calendar-month hebrew-date))
(y (extract-calendar-year hebrew-date))
(last-month-of-y (hebrew-calendar-last-month-of-year y))
(date))
(setq m (+ m 3 (- month)))
(cond
((> m last-month-of-y)
(progn
(setq m (- m last-month-of-y))
(setq y (1+ y))))
((< m 1)
(progn
(setq y (1- y))
(setq m (+ m (hebrew-calendar-last-month-of-year y))))))
(if (< m 6);; (MONTH, DAY, y) might be visible
(let ((date (calendar-gregorian-from-absolute
(calendar-absolute-from-hebrew (list month day y)))))
(if (calendar-date-is-visible-p date)
(list date string)))))))
;; The functions from here on were written by Nachum Dershowitz in Common Lisp
;; and rewritten in Emacs Lisp by E.M.R.
(defconst hebrew-calendar-epoch (list 247 20 785)
"Extrapolated new moon for year 0 Gregorian.")
(defconst hebrew-calendar-regular-year (list 354 8 876)
"Excess length of 12 (mean) lunations.")
(defconst hebrew-calendar-leap-year (list 383 21 589)
"Excess length of 13 lunations.")
(defconst hebrew-calendar-cycle (list 6939 16 595)
"Length of 235 lunations (19 year Metonic cycle).")
(defun extract-hebrew-calendar-days (interval)
"Extract the day part of INTERVAL which has the form (days hours parts)."
(car interval))
(defun extract-hebrew-calendar-hours (interval)
"Extract the hours part of INTERVAL which has the form (days hours parts)."
(car (cdr interval)))
(defun extract-hebrew-calendar-parts (interval)
"Extract the parts part of INTERVAL which has the form (days hours parts)."
(car (cdr (cdr interval))))
(defun normalize-hebrew-calendar-interval (interval)
"Returns a normalized version of INTERVAL.
Normalized in the sense that the number of hours is less than 24 and
the number of parts is less than 1080."
(let ((hours (+ (extract-hebrew-calendar-hours interval)
(/ (extract-hebrew-calendar-parts interval) 1080))))
(list (+ (extract-hebrew-calendar-days interval) (/ hours 24))
(% hours 24)
(% (extract-hebrew-calendar-parts interval) 1080))))
(defun add-hebrew-calendar-intervals (&rest l)
"Add the list L of intervals and normalize."
(let ((sum (list 0 0 0)))
(while (car l)
(setq sum
(list (+ (extract-hebrew-calendar-days (car l))
(extract-hebrew-calendar-days sum))
(+ (extract-hebrew-calendar-hours (car l))
(extract-hebrew-calendar-hours sum))
(+ (extract-hebrew-calendar-parts (car l))
(extract-hebrew-calendar-parts sum))))
(setq l (cdr l)))
(normalize-hebrew-calendar-interval sum)))
(defun multiply-hebrew-calendar-interval (interval c)
"Multiply INTERVAL by C."
(normalize-hebrew-calendar-interval
(list (* (extract-hebrew-calendar-days interval) c)
(* (extract-hebrew-calendar-hours interval) c)
(* (extract-hebrew-calendar-parts interval) c))))
(defun hebrew-calendar-cycles (year)
"Number of complete cycles before YEAR+3761."
(/ (1- year) 19))
(defun years-into-hebrew-calendar-cycle (year)
"Number of years prior to YEAR+3761 in the current cycle."
(% (1- year) 19))
(defun prior-leap-years-in-hebrew-calendar-cycle (year)
"Number of leap years prior to YEAR+3761 in the current cycle."
(let ((y (years-into-hebrew-calendar-cycle year)))
(cond ((>= y 18) 7) ((>= y 15) 6) ((>= y 12) 5)
((>= y 9) 4) ((>= y 7) 3) ((>= y 4) 2)
((>= y 1) 1) (t 0))))
(defun prior-regular-years-in-hebrew-calendar-cycle (year)
"Number of regular (non-leap) years prior to YEAR+3761 in the current cycle."
(- (years-into-hebrew-calendar-cycle year)
(prior-leap-years-in-hebrew-calendar-cycle year)))
(defun hebrew-calendar-new-year-mean-conjunction (year)
"The time of week of the mean conjunction of Tishri of YEAR+3761."
(let ((interval
(add-hebrew-calendar-intervals
hebrew-calendar-epoch
(multiply-hebrew-calendar-interval
hebrew-calendar-cycle
(hebrew-calendar-cycles year))
(multiply-hebrew-calendar-interval
hebrew-calendar-regular-year
(prior-regular-years-in-hebrew-calendar-cycle year))
(multiply-hebrew-calendar-interval
hebrew-calendar-leap-year
(prior-leap-years-in-hebrew-calendar-cycle year)))))
interval))
(defun hebrew-calendar-new-year-day (year)
"Absolute date of 1 Tishri (Rosh Hashanah) of YEAR+3761."
(let* ((m (hebrew-calendar-new-year-mean-conjunction year))
(day (extract-hebrew-calendar-days m))
(hour (extract-hebrew-calendar-hours m))
(part (extract-hebrew-calendar-parts m))
;; Take into account any delay.
(day1
(if (or (>= hour 18)
(and (= (% day 7) 2)
(not (hebrew-calendar-leap-year-p year))
(or (> hour 9)
(and (= hour 9) (>= part 204))))
(and (= (% day 7) 1)
(hebrew-calendar-leap-year-p (1- year))
(or (> hour 15)
(and (= hour 15) (>= part 589)))))
(1+ day)
day)))
(if (memq (% day1 7) (list 0 3 5))
(1+ day1)
day1)))
(defun hebrew-calendar-leap-year-p (year)
"T if YEAR+3761 is a leap year."
(memq
(years-into-hebrew-calendar-cycle year)
(list 0 3 6 8 11 14 17)))
(defun hebrew-calendar-long-heshvan-p (year)
"T if Heshvan is long in YEAR+3761."
(if (hebrew-calendar-leap-year-p year)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 385)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 355)))
(defun hebrew-calendar-short-kislev-p (year)
"T if Kislev is short in YEAR+3761."
(if (hebrew-calendar-leap-year-p year)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 383)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 353)))
(defun hebrew-calendar-last-day-of-month (month year)
"The last day of MONTH in YEAR+3761."
(if (or (memq month (list 2 4 6 10 13))
(and (= month 12) (not (hebrew-calendar-leap-year-p year)))
(and (= month 8) (not (hebrew-calendar-long-heshvan-p year)))
(and (= month 9) (hebrew-calendar-short-kislev-p year)))
29
30))
(defun hebrew-calendar-date-beyond-date (days month year)
"Returns the Hebrew date that is DAYS beyond the start of MONTH, YEAR+3761.
That date must be in the same year."
(let ((len (hebrew-calendar-last-day-of-month month year)))
(while (> days len)
(setq days (- days len))
(setq month (1+ (% month (hebrew-calendar-last-month-of-year year))))
(setq len (hebrew-calendar-last-day-of-month month year))))
(list days month year))
(defun hebrew-calendar-days-from-tishri (days month year)
"Number of days, inclusive, from 1 Tishri to DAYS, MONTH, YEAR+3761."
(while (/= month 7)
(setq month
(if (= month 1)
(hebrew-calendar-last-month-of-year year)
(1- month)))
(setq days (+ days (hebrew-calendar-last-day-of-month month year))))
days)
(defun hebrew-calendar-year-length (year)
"The number of days in Hebrew calendar YEAR+3761."
(- (hebrew-calendar-new-year-day year)
(hebrew-calendar-new-year-day (1- year))))
(defun hebrew-calendar-last-month-of-year (year)
"The last month of the Hebrew calendar YEAR+3761."
(if (hebrew-calendar-leap-year-p year)
13
12))
(defun calendar-hebrew-from-absolute (date)
"Compute the Hebrew date (month day year) corresponding to absolute DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let ((month 7)
(day 1)
(year (+ 3761 (/ date 366))))
(while (> date (calendar-absolute-from-hebrew (list 6 29 year)))
(setq year (1+ year)))
(let ((length (hebrew-calendar-last-month-of-year (+ 3761 year))))
(while (> date
(calendar-absolute-from-hebrew
(list month
(hebrew-calendar-last-day-of-month month (+ 3761 year))
year)))
(setq month (1+ (% month length)))))
(setq day (1+
(- date (calendar-absolute-from-hebrew (list month 1 year)))))
(list month day year)))
(defun calendar-absolute-from-hebrew (date)
"Absolute date of Hebrew DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (- (extract-calendar-year date) 3761)))
(+
-1
(hebrew-calendar-new-year-day year)
(hebrew-calendar-days-from-tishri day month year))))reingold@m.cs.uiuc.edu (04/03/89)
I apologize for posting yet another version of calendar.el (to be part of
version 19), but I lost track of many people who made requests, my email
to others consistently bounces, and there have been some significant
improvements.
The improvements in the version below are:
* The holidays are integrated into the diary and are a bit faster.
* A fancy diary display is available (in a neat, day-by-day format).
* Displaying the diary creates a list of entries that makes tasks
like appointment notification possible (two people have been
working on such notification).
Honestly, I plan no further postings. In fact, I plan never to write
another line of code for distribution!!
-----------------------------------------------------------------------------
;; Calendar and diary functions.
;; Copyright (C) 1988, 1989 Free Software Foundation, Inc.
;; This file is part of GNU Emacs.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY. No author or distributor
;; accepts responsibility to anyone for the consequences of using it
;; or for whether it serves any particular purpose or works at all,
;; unless he says so in writing. Refer to the GNU Emacs General Public
;; License for full details.
;; Everyone is granted permission to copy, modify and redistribute
;; GNU Emacs, but only under the conditions described in the
;; GNU Emacs General Public License. A copy of this license is
;; supposed to have been given to you along with GNU Emacs so you
;; can know your rights and responsibilities. It should be in a
;; file named COPYING. Among other things, the copyright notice
;; and this notice must be preserved on all copies.
;; This collection of functions implements a calendar window and diary. It
;; generates a calendar for the current month, together with the previous and
;; coming months, or for any other three-month period. The calendar can be
;; shifted forward and backward in the window to show months in the past or
;; future; the cursor can move forward and backward by days, weeks, or months,
;; making it possible, for instance, to jump to the date a specified number
;; of days, weeks, or months from the date under the cursor. The user can
;; display a list of holidays and other notable days for the period shown;
;; the notable days can be marked on the calendar, if desired. The user can
;; also specify that dates having corresponding diary entries (in a file that
;; the user specifies) be marked; the diary entries for any date can be viewed
;; in a separate window. The diary and the notable days can be viewed
;; independently of the calendar. Dates can be translated from the (usual)
;; Gregorian calendar to the Julian (old style) calendar, the Hebrew calendar,
;; and the Islamic calendar.
;; Comments, corrections, and improvements should be sent to
;; Edward M. Reingold Department of Computer Science
;; (217) 333-6733 University of Illinois at Urbana-Champaign
;; reingold@a.cs.uiuc.edu 1304 West Springfield Avenue
;; Urbana, Illinois 61801
;; GNU Emacs users too numerous to list pointed out a variety of problems
;; with earlier forms of the `infinite' sliding calendar and suggested some
;; of the features included in this package. Especially significant in this
;; regard was the suggestion of mark-diary-entries and view-diary-entries,
;; together ideas for their implementation, by
;; Michael S. Littman Cognitive Science Research Group
;; (201)-829-5155 Bell Communications Research
;; mlittman@wind.bellcore.com 445 South St. Box 1961 (2L-331)
;; Morristown, NJ 07960-1961
;; The algorithms for the Hebrew calendar are those of the Rambam (Rabbi Moses
;; Maimonides), from his Mishneh Torah, as implemented by
;; Nachum Dershowitz Department of Computer Science
;; (217) 333-4219 University of Illinois at Urbana-Champaign
;; nachum@a.cs.uiuc.edu 1304 West Springfield Avenue
;; Urbana, Illinois 61801
(defvar view-diary-entries-initially nil
"*If T, the diary entries for the current date will be displayed on entry.
The diary is displayed in another window when the calendar is first displayed,
if the current date is visible. The number of days of diary entries displayed
is governed by the variable `number-of-diary-entries'.")
(defvar number-of-diary-entries 1
"*Specifies how many days of diary entries are to be displayed initially.
This variable affects the diary display when the command M-x diary is used,
or if the value of the variable `view-diary-entries-initially' is t. For
example, if the default value 1 is used, then only the current day's diary
entries will be displayed. If the value 2 is used, then both the current
day's and the next day's entries will be displayed. The value can also be
a vector such as [0 2 2 2 2 4 1]; this value will cause no diary entries to
be displayed on Sunday, the current date's and the next day's diary entries
to be displayed Monday through Thursday, Friday through Monday's entries to
be displayed on Friday, and only Saturday's entries to be displayed on
Saturday. This variable does not affect the diary display with the `d'
command from the calendar; in that case, the prefix argument controls the
number of days of diary entries displayed.")
(defvar mark-diary-entries-in-calendar nil
"*If t, dates with diary entries will be marked in the calendar window.
The marking symbol is specifed by the variable `diary-entry-marker'.")
(defvar diary-entry-marker "+"
"*The symbol used to mark dates that have diary entries.")
(defvar view-calendar-holidays-initially nil
"*If t, the holidays for the current three month period will be displayed
on entry. The holidays are displayed in another window when the calendar is
first displayed.")
(defvar mark-holidays-in-calendar nil
"*If t, dates of holidays will be marked in the calendar window.
The marking symbol is specified by the variable `calendar-holiday-marker'.")
(defvar calendar-holiday-marker "*"
"*The symbol used to mark notable in the calendar.")
(defvar initial-calendar-window-hook nil
"*List of functions to be called when the calendar window is first opened.
The functions invoked are called after the calendar window is opened, but
once opened is never called again. Leaving the calendar with the `q' command
and reentering it will cause these functions to be called again.")
(defvar today-visible-calendar-hook nil
"*List of functions called whenever the current date is visible.
This can be used, for example, to replace today's date with asterisks; a
function calendar-star-date is included for this purpose:
(setq today-visible-calendar-hook 'calendar-star-date)
It could also be used to mark the current date with `*'; a function is also
provided for this:
(setq today-visible-calendar-hook 'calendar-mark-today)
The corresponding variable `today-invisible-calendar-hook' is the list of
functions called when the calendar function was called when the current
date is not visible in the window.
Other than the use of the provided functions, the changing of any
characters in the calendar buffer by the hooks may cause the failure of the
functions that move by days and weeks.")
(defvar today-invisible-calendar-hook nil
"*List of functions called whenever the current date is not visible.
The corresponding variable `today-visible-calendar-hook' is the list of
functions called when the calendar function was called when the current
date is visible in the window.
Other than the use of the provided functions, the changing of any
characters in the calendar buffer by the hooks may cause the failure of the
functions that move by days and weeks.")
(defvar diary-file "~/diary"
"*Name of the file in which one's personal diary of dates is kept.
The file's entries are lines in the form DAY, MONTH/DAY or MONTH/DAY/YEAR
at the beginning of the line, followed by a nondigit; the remainder of the
line is the diary entry string for that date. MONTH and DAY are one or two
digit numbers, YEAR is a number and must be written in full. If the date
does not contain a year, it is generic and applies to any year; if it does
not contain a year or a month, it applies to any month.
Entries can also in the form MONTHNAME DAY or MONTHNAME DAY, YEAR or * DAY,
at the beginning of the line, where the month's name can be spelled in
full, abbreviated to three characters (with or without a period),
capitalized or not. If the date does not contain a year, it is generic and
applies to any year. The form * DAY is generic and applies to any month of
any year.
Entries can be of the form DAYNAME at the beginning of a line, followed by
a nonletter. The day name can be spelled out in full (e.g., `Tuesday') or
it can be abbreviated to three characters (e.g., `Tue'); it need not be
capitalized. DAYNAME entries apply to any date on which is on that day of
the week.
A diary entry can be preceded by a diary-nonmarking-symbol (ordinarily `&')
to make that entry nonmarking--that is, it will not be marked on dates in
the calendar window but will appear in a diary window.
Multiline diary entries are made by indenting lines after the first with
either a TAB or one or more spaces.
Lines not in one the above formats are ignored. Here are some sample diary
entries:
12/22/1988 Twentieth wedding anniversary!!
&1/1. Happy New Year!
10/22 Ruth's birthday.
21: Payday
Tuesday--weekly meeting with grad students at 10am
Supowit, Shen, Bitner, and Kapoor to attend.
1/13/1989 Friday the thirteenth!!
&thu 4pm squash game with Lloyd.
mar 16 Dad's birthday
April 15, 1989 Income tax due.
&* 15 time cards due.
If the first line of a diary entry consists only of the date or day name with
no trailing blanks or punctuation, then that line will not be displayed in the
diary window; only the continuation lines will be shown. For example, the
single diary entry
02/11/1989
Bill Blattner visits Princeton today
2pm Cognitive Studies Committee meeting
2:30-5:30 Lizzie at Lawrenceville for `Group Initiative'
4:00pm Jamie Tappenden
7:30pm Dinner at George and Ed's for Alan Ryan
7:30-10:00pm dance at Stewart Country Day School
will appear in the diary window without the date line at the beginning. This
facility allows the diary window to look neater, but can cause confusion if
used with more than one day's entries displayed.")
(defvar diary-nonmarking-symbol "&"
"*The symbol used to indicate that a diary entry is not to be marked in the
calendar window.")
(defvar print-diary-entries-hook
'(add-diary-heading lpr-buffer (lambda nil (kill-buffer temp-buffer)))
"*List of functions to be called after a temporary buffer is prepared
with the diary entries currently visible in the diary buffer. The default
value adds a heading (formed from the information in the mode line of the
diary buffer), does the printing, and kills the buffer. Other uses might
include, for example, rearranging the lines into order by day and time,
saving the buffer instead of deleting it, or changing the function used to
do the printing.")
(defvar list-diary-entries-hook
'(lambda nil
(if diary-entries-list
(display-buffer (get-file-buffer diary-file))
(message "No diary entries for %s %s" date-string holiday-string)))
"*List of functions to be called after the diary buffer is prepared.
Ordinarily, this just displays the diary buffer (with holidays indicated in
the mode line), if there are any relevant entries. At the time these
functions are called, the variable `diary-entries-list' is a list, in order
by date, of all relevant diary entries in the form of ((MONTH DAY YEAR)
STRING), where string is the diary entry for the given date. This can be
used, for example, to handle appointment notification, prepare a different
buffer for display (perhaps combined with holidays), or produce hard copy
output. A function `prepare-fancy-diary-buffer' is provided as an
alternative choice for this hook; this function prepares a special
noneditable diary buffer with the relevant diary entries that has neat
day-by-day arrangement with headings. The fancy buffer will show the
holidays unless the variable `holidays-in-diary-buffer' is set to nil.")
(defvar holidays-in-diary-buffer t
"*If t, the holidays will be indicated in the mode line of the diary buffer
(or in the fancy diary buffer next to the date). This slows down the diary
functions somewhat; setting it to nil will make the diary display faster.")
(defvar calendar-holidays
'((fixed 1 1 "New Year's Day")
(float 1 1 3 "Martin Luther King Day")
(fixed 2 2 "Ground Hog Day")
(fixed 2 14 "Valentine's Day")
(float 2 1 3 "President's Day")
(fixed 3 17 "St. Patrick's Day")
(special calendar-easter-etc)
(fixed 4 1 "April Fool's Day")
(hebrew 1 15 "Passover")
(float 4 0 1 "Beginning of Daylight Savings Time")
(float 5 0 2 "Mother's Day")
(float 5 1 5 "Memorial Day")
(hebrew 3 6 "Shavuoth")
(fixed 6 14 "Flag Day")
(float 6 0 3 "Father's Day")
(fixed 7 4 "Independence Day")
(float 9 1 1 "Labor Day")
(special calendar-rosh-hashanah-etc)
(float 10 1 2 "Columbus Day")
(float 10 0 5 "End of Daylight Savings Time")
(fixed 10 31 "Halloween")
(fixed 11 11 "Veteran's Day")
(float 11 4 4 "Thanksgiving")
(hebrew 9 25 "Hanukah")
(fixed 12 25 "Christmas")
(julian 12 25 "Eastern Orthodox Christmas")
(islamic 1 1 "Islamic New Year")
(islamic 9 1 "Ramadan Begins"))
"List of notable days for the command M-x holidays.
Additional holidays are easy to add to the list. The possible forms are
fixed a fixed date on the Gregorian calendar
float the i-th x-day on the Gregorian calendar (0 for Sunday, etc.)
hebrew a Hebrew calendar date
islamic an Islamic calendar date
julian a Julian calendar date
special dates requiring special computation
For example, to add Bastille Day, July 14, add
(fixed 7 14 \"Bastille Day\")
to the list. To add Irish Bank Day, observed in Ireland on the first Monday
in June, add
(float 6 2 1 \"Irish Bank Day\")
to the list (the last Monday would be specified with `5' instead of `1').
To add the last day of Hanukah to the list, use
(hebrew 10 2 \"Last day of Hanukah\")
since the Hebrew months are numbered with 1 starting from Nisan, while to
add the Islamic feast celebrating Mohammed's birthday use
(islamic 3 12 \"Mohammed's Birthday\")
since the Islamic months are numbered from 1 starting with Muharram. To
add Thomas Jefferson's birthday, April 2, 1743 (Julian), use
(julian 4 2 \"Jefferson's Birthday\")
while to include the phases of the moon, add
(special lunar-phases)
to the holiday list, where `lunar-phases' is an Emacs-Lisp function that
you've written to return a (possibly empty) list of the relevant VISIBLE
dates with messages such as
(((2 6 1989) \"New Moon\") ((2 12 1989) \"First Quarter Moon\") ... )
")
(defconst calendar-buffer "*Calendar*"
"Name of the buffer used for the calendar.")
(defconst holiday-buffer "*Holidays*"
"Name of the buffer used for the displaying the holidays.")
(defconst fancy-diary-buffer "*Fancy Diary Entries*"
"Name of the buffer used for the optional fancy display of the diary.")
(defmacro increment-calendar-month (mon yr n)
"Move the variables MON and YR to the month and year N months forward
if N is positive or backward if N is negative."
(` (let (( macro-y (+ (* (, yr) 12) (, mon) -1 (, n) )))
(setq (, mon) (1+ (% macro-y 12) ))
(setq (, yr) (/ macro-y 12)))))
(defmacro calendar-for-loop (var from init to final do &rest body)
"Execute a for loop."
(` (let (( (, var) (1- (, init)) ))
(while (>= (, final) (setq (, var) (1+ (, var))))
(,@ body)))))
(defun calendar (&optional arg)
"Display a three-month calendar in another window.
The three months appear side by side, with the current month in the middle
surrounded by the previous and next months. The cursor is put on today's date.
This function is suitable for execution in a .emacs file; appropriate setting
of the variable `view-diary-entries-initially' will cause the diary entries for
the current date to be displayed in another window. The value of the variable
`number-of-diary-entries' controls the number of days of diary entries
displayed upon initial display of the calendar.
An optional prefix argument ARG causes the calendar displayed to be ARG
months in the future if ARG is positive or in the past if ARG is negative;
in this case the cursor goes on the first day of the month.
Once in the calendar window, future or past months can be moved into view.
Arbitrary months can be displayed, or the calendar can be scrolled forward
or backward.
The cursor can be moved forward or backward by one day, one week, one month,
or one year. All of these commands take prefix arguments which, when negative,
cause movement in the opposite direction. For convenience, the digit keys
and the minus sign are automatically prefixes. The window is replotted as
necessary to display the desired date.
Diary entries can be marked on the calendar or displayed in another window.
Use M-x describe-mode for details of the key bindings in the calendar window.
The Gregorian calendar is assumed.
After preparing the calendar window initially, the hooks given by the variable
`initial-calendar-window-hook' are run.
The hooks given by the variable `today-visible-calendar-hook' are run
everytime the calendar window gets shifted, if the current date is visible
in the window. If it is not visible, the hooks given by the variable
`today-invisible-calendar-hook' are run. Thus, for example, setting
`today-visible-calendar-hook' to 'calendar-star-date will cause today's date
to be replaced by asterisks to highlight it whenever it is in the window."
(interactive "P")
(setq arg (if arg (prefix-numeric-value arg) 0))
(set-buffer (get-buffer-create calendar-buffer))
(calendar-mode)
(setq calendar-window-configuration (current-window-configuration))
(let ((pop-up-windows t)
(split-height-threshold 1000))
(pop-to-buffer calendar-buffer)
(regenerate-calendar-window arg)
(let ((date (list current-month current-day current-year)))
(if (and view-diary-entries-initially (calendar-date-is-visible-p date))
(view-diary-entries
(if (vectorp number-of-diary-entries)
(aref number-of-diary-entries (calendar-day-of-week date))
number-of-diary-entries))))
(let* ((diary-buffer (get-file-buffer diary-file))
(diary-window (if diary-buffer (get-buffer-window diary-buffer)))
(split-height-threshold (if diary-window 2 1000)))
(if view-calendar-holidays-initially
(list-calendar-holidays))))
(run-hooks 'initial-calendar-window-hook))
(defun diary (&optional arg)
"Generate the diary window for ARG days starting with the current date.
If no argument is provided, the number of days of diary entries is governed
by the variable `number-of-diary-entries'. This function is suitable for
execution in a .emacs file."
(interactive "P")
(if (and diary-file (file-exists-p diary-file))
(let ((date (calendar-current-date)))
(list-diary-entries
date
(cond
(arg (prefix-numeric-value arg))
((vectorp number-of-diary-entries)
(aref number-of-diary-entries (calendar-day-of-week date)))
(t number-of-diary-entries))))
(error "You don't have a diary file!")))
(defun holidays ()
"Display the holidays for last month, this month, and next month.
This function is suitable for execution in a .emacs file."
(interactive)
(save-excursion
(let* ((date (calendar-current-date))
(displayed-month (extract-calendar-month date))
(displayed-year (extract-calendar-year date)))
(list-calendar-holidays))))
(defun regenerate-calendar-window (&optional arg)
"Generate the calendar window, offset from the current date by ARG months."
(if (not arg) (setq arg 0))
(let* ((buffer-read-only nil)
(date (calendar-current-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(day-in-week (calendar-day-of-week date))
(date-string
(concat (substring (calendar-day-name date) 0 3) ", "
(substring (calendar-month-name month) 0 3) " "
(int-to-string day) ", "
(int-to-string year))))
(setq mode-line-format
(format
"C-X < Calendar ? help/o other/c current %17s C-X >"
date-string))
(setq current-month month)
(setq current-day day)
(setq current-year year)
(increment-calendar-month month year arg)
(generate-calendar month year))
(if mark-holidays-in-calendar
(mark-calendar-holidays))
(unwind-protect
(if mark-diary-entries-in-calendar
(mark-diary-entries))
(set-buffer-modified-p nil)
(or (one-window-p t)
(/= (screen-width) (window-width))
(shrink-window (- (window-height) 9)))
(if (and (<= arg 1) (>= arg -1))
(progn;; When the current date is on the screen.
(calendar-cursor-to-visible-date
(list current-month current-day current-year))
(run-hooks 'today-visible-calendar-hook))
;; When the current date is not on the screen.
(calendar-cursor-to-visible-date
(list displayed-month 1 displayed-year))
(run-hooks 'today-invisible-calendar-hook))))
(defun generate-calendar (month year)
"Generate a three-month Gregorian calendar centered around MONTH, YEAR."
(if (< (+ month (* 12 (1- year))) 2)
(error "Months before February, 1 AD are not available."))
(setq displayed-month month)
(setq displayed-year year)
(setq displayed-calendar-holiday-list nil)
(erase-buffer)
(increment-calendar-month month year -1)
(calendar-for-loop i from 0 to 2 do
(generate-calendar-month month year (+ 5 (* 25 i)))
(increment-calendar-month month year 1)))
(defun generate-calendar-month (month year indent)
"Produce a calendar for MONTH, YEAR on the Gregorian calendar.
The calendar is inserted in the buffer starting at the line on which point
is currently located, but indented INDENT spaces. The indentation is done
from the first character on the line and does not disturb the first INDENT
characters on the line."
(let* ((first-day-of-month (calendar-day-of-week (list month 1 year)))
(first-saturday (- 7 first-day-of-month))
(last (calendar-last-day-of-month month year)))
(goto-char (point-min))
(calendar-insert-indented
(format " %s %d" (calendar-month-name month) year) indent t)
(calendar-insert-indented " S M Tu W Th F S" indent t)
(calendar-insert-indented "" indent);; Move to appropriate spot on line
;; Add blank days before the first of the month
(calendar-for-loop i from 1 to first-day-of-month do
(insert " "))
;; Put in the days of the month
(calendar-for-loop i from 1 to last do
(insert (format "%2d " i))
(and (= (% i 7) (% first-saturday 7))
(/= i last)
(calendar-insert-indented "" 0 t) ;; Force onto following line
(calendar-insert-indented "" indent)))));; Go to proper spot
(defun calendar-insert-indented (string indent &optional newline)
"Insert STRING at column INDENT.
If the optional parameter NEWLINE is t, leave point at start of next line,
inserting a newline if there was no next line; otherwise, leave point after
the inserted text. Value is always t."
;; Try to move to that column.
(move-to-column indent)
;; If line is too short, indent out to that column.
(if (< (current-column) indent)
(indent-to indent))
(insert string)
;; Advance to next line, if requested.
(if newline
(progn
(end-of-line)
(if (eobp)
(newline)
(forward-line 1))))
t)
(defvar calendar-mode-map nil)
(if calendar-mode-map
nil
(setq calendar-mode-map (make-sparse-keymap))
(calendar-for-loop i from 0 to 9 do
(define-key calendar-mode-map (int-to-string i) 'digit-argument))
(define-key calendar-mode-map "-" 'negative-argument)
(define-key calendar-mode-map "\C-x>" 'shift-calendar-right)
(define-key calendar-mode-map "\ev" 'shift-calendar-right-three-months)
(define-key calendar-mode-map "\C-x<" 'shift-calendar-left)
(define-key calendar-mode-map "\C-v" 'shift-calendar-left-three-months)
(define-key calendar-mode-map "\C-b" 'calendar-backward-day)
(define-key calendar-mode-map "\C-p" 'calendar-backward-week)
(define-key calendar-mode-map "\e[" 'calendar-backward-month)
(define-key calendar-mode-map "\C-x[" 'calendar-backward-year)
(define-key calendar-mode-map "\C-f" 'calendar-forward-day)
(define-key calendar-mode-map "\C-n" 'calendar-forward-week)
(define-key calendar-mode-map "\e]" 'calendar-forward-month)
(define-key calendar-mode-map "\C-x]" 'calendar-forward-year)
(define-key calendar-mode-map "\C-a" 'calendar-beginning-of-week)
(define-key calendar-mode-map "\C-e" 'calendar-end-of-week)
(define-key calendar-mode-map "\ea" 'calendar-beginning-of-month)
(define-key calendar-mode-map "\ee" 'calendar-end-of-month)
(define-key calendar-mode-map "\e<" 'calendar-beginning-of-year)
(define-key calendar-mode-map "\e>" 'calendar-end-of-year)
(define-key calendar-mode-map "c" 'calendar-current-month)
(define-key calendar-mode-map "o" 'calendar-other-month)
(define-key calendar-mode-map "q" 'exit-calendar)
(define-key calendar-mode-map "a" 'list-calendar-holidays)
(define-key calendar-mode-map "h" 'calendar-cursor-holidays)
(define-key calendar-mode-map "x" 'mark-calendar-holidays)
(define-key calendar-mode-map "u" 'calendar-unmark)
(define-key calendar-mode-map "m" 'mark-diary-entries)
(define-key calendar-mode-map "d" 'view-diary-entries)
(define-key calendar-mode-map "s" 'show-all-diary-entries)
(define-key calendar-mode-map "J" 'cursor-to-julian-calendar-date)
(define-key calendar-mode-map "H" 'cursor-to-hebrew-calendar-date)
(define-key calendar-mode-map "I" 'cursor-to-islamic-calendar-date)
(define-key calendar-mode-map "?" 'describe-mode))
;; Calendar mode is suitable only for specially formatted data.
(put 'calendar-mode 'mode-class 'special)
(defun calendar-mode ()
"A major mode for the sliding calendar window and diary.
The commands for cursor movement are:\\<calendar-mode-map>
\\[calendar-forward-day] one day forward \\[calendar-backward-day] one day backward
\\[calendar-forward-week] one week forward \\[calendar-backward-week] one week backward
\\[calendar-forward-month] one month forward \\[calendar-backward-month] one month backward
\\[calendar-forward-year] one year forward \\[calendar-backward-year] one year backward
\\[calendar-beginning-of-week] beginning of week \\[calendar-end-of-week] end of week
\\[calendar-beginning-of-month] beginning of month \\[calendar-end-of-month] end of month
\\[calendar-beginning-of-year] beginning of year \\[calendar-end-of-year] end of year
The commands for calendar movement are:
\\[shift-calendar-right] shift one month right \\[shift-calendar-left] shift one month left
\\[shift-calendar-right-three-months] shift 3 months right \\[shift-calendar-left-three-months] shift 3 months left
\\[calendar-current-month] display current date \\[calendar-other-month] display another date
Except for the last two, all of the above commands take prefix arguments
that multiply their affect. For convenience, the digit keys and the minus
sign are bound to digit-argument, so they need not be prefixed with ESC.
The following commands deal with holidays and other notable days:
\\[calendar-cursor-holidays] give holidays for the date specified by the cursor
\\[mark-calendar-holidays] mark notable days \\[calendar-unmark] unmark dates
\\[list-calendar-holidays] display notable days
The command M-x holidays causes the notable dates for the current month, and
the preceding and succeeding months, to be displayed, independently of the
calendar.
The following commands control the diary:
\\[mark-diary-entries] mark diary entries \\[calendar-unmark] unmark dates
\\[view-diary-entries] display diary entries \\[show-all-diary-entries] show all diary entries
\\[print-diary-entries] print diary entries
Displaying the diary entries causes the dairy entries from the diary-file
(for the date indicated by the cursor in the calendar window) to be
displayed in another window. This function takes an integer argument that
specifies the number of days of calendar entries to be displayed, starting
with the date indicated by the cursor.
The command \\[print-diary-entries] prints the diary buffer (as it appears)
on the line printer.
The command M-x diary causes the diary entries for the current date to be
displayed, independently of the calendar. The number of days of entries is
governed by number-of-diary-entries.
The format of the entries in the diary file is described in the
documentation string for the variable diary-file.
When diary entries are in view in the window, they can be edited. It is
important to keep in mind that the buffer displayed contains the entire
diary file, but with portions of it concealed from view. This means, for
instance, that the forward-char command can put the cursor at what appears
to be the end of the line, but what is in reality the middle of some
concealed line. BE CAREFUL WHEN EDITING THE DIARY ENTRIES! (Inserting
additional lines or adding/deleting characters in the middle of a visible
line will not cause problems; watch out for end-of-line, however--it may
put you at the end of a concealed line far from where the cursor appears to
be!) BEFORE EDITING THE DIARY IT IS BEST TO DISPLAY THE ENTIRE FILE WITH
show-all-diary-entries. BE SURE TO WRITE THE FILE BEFORE EXITING FROM THE
CALENDAR.
Equivalent dates on the Julian, Hebrew, and Islamic calendars can be
determined by
\\[cursor-to-julian-calendar-date] show equivalent date on the Julian calendar
\\[cursor-to-hebrew-calendar-date] show equivalent date on the Hebrew calendar
\\[cursor-to-islamic-calendar-date] show equivalent date on the Islamic calendar
To exit from the calendar use
\\[exit-calendar] exit from calendar
The variable `view-diary-entries-initially', whose default is nil, can be
set to to t cause diary entries for the current date will be displayed in
another window when the calendar is first displayed, if the current date is
visible. The variable `number-of-diary-entries' controls number of days of
diary entries that will be displayed initially or with the command M-x
diary. For example, if the default value 1 is used, then only the current
day's diary entries will be displayed. If the value 2 is used, both the
current day's and the next day's entries will be displayed. The value can
also be a vector: If the value is [0 2 2 2 2 4 1] then no diary entries
will be displayed on Sunday, the current date's and the next day's diary
entries will be displayed Monday through Thursday, Friday through Monday's
entries will be displayed on Friday, while on Saturday only that day's
entries will be displayed.
The variable `view-calendar-holidays-initially' can be set to t to cause
the holidays for the current three month period will be displayed on entry
to the calendar. The holidays are displayed in another window.
The variable `mark-diary-entries-in-calendar' can be set to t to cause any
dates visible with calendar entries to be marked with the symbol specifed
by the variable `diary-entry-marker', normally a plus sign.
The variable `initial-calendar-window-hook', whose default value is nil,
is list of functions to be called when the calendar window is first opened.
The functions invoked are called after the calendar window is opened, but
once opened is never called again. Leaving the calendar with the `q' command
and reentering it will cause these functions to be called again.
The variable `today-visible-calendar-hook', whose default value is nil,
is the list of functions called after the calendar buffer has been prepared
with the calendar when the current date is visible in the window.
This can be used, for example, to replace today's date with asterisks; a
function calendar-star-date is included for this purpose:
(setq today-visible-calendar-hook 'calendar-star-date)
It could also be used to mark the current date with `*'; a function is also
provided for this:
(setq today-visible-calendar-hook 'calendar-mark-today)
The variable `today-invisible-calendar-hook', whose default value is nil,
is the list of functions called after the calendar buffer has been prepared
with the calendar when the current date is not visible in the window.
The variable `list-diary-entries-hook' is the list of functions called
after the diary buffer is prepared. The default value simply displays the
diary file using selective-display to conceal irrelevant diary entries. An
alternative function `prepare-fancy-diary-buffer' is provided that, when
used as the `list-diary-entries-hook', causes a noneditable buffer to be
prepared with a neatly organized day-by-day listing of relevant diary
entries, together with any known holidays. The inclusion of the holidays
slows this fancy display of the diary; to speed it up, set the variable
`holidays-in-diary-buffer' to nil.
The variable `print-diary-entries-hook' is the list of functions called
after a temporary buffer is prepared with the diary entries currently
visible in the diary buffer. The default value of this hook adds a heading
(composed from the diary buffer's mode line), does the printing with the
command lpr-buffer, and kills the temporary buffer. Other uses might
include, for example, rearranging the lines into order by day and time.
The Gregorian calendar is assumed."
(kill-all-local-variables)
(setq major-mode 'calendar-mode)
(setq mode-name "Calendar")
(use-local-map calendar-mode-map)
(setq buffer-read-only t)
(setq indent-tabs-mode nil)
(make-local-variable 'displayed-calendar-holiday-list)
(make-local-variable 'mode-line-format)
(make-local-variable 'calendar-window-configuration);; Windows on entry.
(make-local-variable 'current-month) ;; Current month.
(make-local-variable 'current-day) ;; Current day.
(make-local-variable 'current-year) ;; Current year.
(make-local-variable 'displayed-month);; Month in middle of window.
(make-local-variable 'displayed-year));; Year in middle of window.
(defun exit-calendar ()
"Get out of the calendar window and destroy it and related buffers."
(interactive)
(let ((diary-buffer (get-file-buffer diary-file))
(d-buffer (get-buffer fancy-diary-buffer))
(h-buffer (get-buffer holiday-buffer)))
(if (not diary-buffer)
(progn
(set-window-configuration calendar-window-configuration)
(kill-buffer calendar-buffer)
(if d-buffer (kill-buffer d-buffer))
(if h-buffer (kill-buffer h-buffer)))
(if (or (not (buffer-modified-p diary-buffer))
(yes-or-no-p "Diary modified; do you really want to exit the calendar? "))
(progn
(set-window-configuration calendar-window-configuration)
(kill-buffer calendar-buffer)
(if d-buffer (kill-buffer d-buffer))
(if h-buffer (kill-buffer h-buffer))
(set-buffer diary-buffer)
(set-buffer-modified-p nil)
(kill-buffer diary-buffer))))))
(defun calendar-current-month ()
"Reposition the calendar window so the current date is visible."
(interactive)
(let ((date (calendar-current-date)));; The date might have changed.
(if (calendar-date-is-visible-p date)
(calendar-cursor-to-visible-date date)
(regenerate-calendar-window))))
(defun calendar-forward-month (arg)
"Move the cursor forward ARG months.
Movement is backward if ARG is negative."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let*
((cursor-date (or (calendar-cursor-to-date)
(error "Cursor is not on a date!")))
(month (extract-calendar-month cursor-date))
(day (extract-calendar-day cursor-date))
(year (extract-calendar-year cursor-date)))
(increment-calendar-month month year arg)
(let ((last (calendar-last-day-of-month month year)))
(if (< last day)
(setq day last)))
;; Put the new month on the screen, if needed, and go to the new date.
(let ((new-cursor-date (list month day year)))
(if (not (calendar-date-is-visible-p new-cursor-date))
(calendar-other-month month year))
(calendar-cursor-to-visible-date new-cursor-date))))
(defun calendar-forward-year (arg)
"Move the cursor forward by ARG years.
Movement is backward if ARG is negative."
(interactive "p")
(calendar-forward-month (* 12 arg)))
(defun calendar-backward-month (arg)
"Move the cursor backward by ARG months.
Movement is forward if ARG is negative."
(interactive "p")
(calendar-forward-month (- arg)))
(defun calendar-backward-year (arg)
"Move the cursor backward ARG years.
Movement is forward is ARG is negative."
(interactive "p")
(calendar-forward-month (* -12 arg)))
(defun shift-calendar-left (arg)
"Shift the displayed calendar left by ARG months.
If ARG is negative the calendar is shifted right. Maintains the relative
position of the cursor with respect to the calendar as well as possible."
(interactive "p")
(let ((old-date (calendar-cursor-to-date))
(today (calendar-current-date)))
(if (/= arg 0)
(progn
(regenerate-calendar-window
(+ arg (calendar-interval current-month current-year
displayed-month displayed-year)))
(calendar-cursor-to-visible-date
(cond
((calendar-date-is-visible-p old-date) old-date)
((calendar-date-is-visible-p today) today)
(t (list displayed-month 1 displayed-year))))))))
(defun shift-calendar-right (arg)
"Shift the displayed calendar window right by ARG months.
If ARG is negative the calendar is shifted left. Maintains the relative
position of the cursor with respect to the calendar as well as possible."
(interactive "p")
(shift-calendar-left (- arg)))
(defun shift-calendar-left-three-months (arg)
"Shift the displayed calendar window left by 3*ARG months.
If ARG is negative the calendar is shifted right. Maintains the relative
position of the cursor with respect to the calendar as well as possible."
(interactive "p")
(shift-calendar-left (* 3 arg)))
(defun shift-calendar-right-three-months (arg)
"Shift the displayed calendar window right by 3*ARG months.
If ARG is negative the calendar is shifted left. Maintains the relative
position of the cursor with respect to the calendar as well as possible."
(interactive "p")
(shift-calendar-left (* -3 arg)))
(defun calendar-current-date ()
"Returns the current date in a list (month day year).
If in the calendar buffer, also sets the current date local variables."
(let* ((date (current-time-string))
(garbage
(string-match
"^\\([A-Z][a-z]*\\) *\\([A-Z][a-z]*\\) *\\([0-9]*\\) .* \\([0-9]*\\)$"
date))
(month
(cdr (assoc
(substring date (match-beginning 2) (match-end 2))
calendar-month-abbrev-list)))
(day
(string-to-int (substring date (match-beginning 3) (match-end 3))))
(year
(string-to-int (substring date (match-beginning 4) (match-end 4)))))
(if (equal (current-buffer) (get-buffer calendar-buffer))
(progn
(setq current-month month)
(setq current-day day)
(setq current-year year)))
(list month day year)))
(defun calendar-cursor-to-date ()
"Returns a list of the month, day, and year of current cursor position.
Returns nil if the cursor is not on a specific day."
(if (and (looking-at "[*0-9]")
(< 2 (count-lines (point-min) (point))))
(save-excursion
(re-search-backward "[^0-9]")
(forward-char 1)
(let*
((day (string-to-int (buffer-substring (point) (+ 3 (point)))))
(day (if (= 0 day) current-day day));; Starred date.
(segment (/ (current-column) 25))
(month (% (+ displayed-month segment -1) 12))
(month (if (= 0 month) 12 month))
(year
(cond
((and (= 12 month) (= segment 0)) (1- displayed-year))
((and (= 1 month) (= segment 2)) (1+ displayed-year))
(t displayed-year))))
(list month day year)))))
(defun calendar-cursor-to-nearest-date ()
"Move the cursor to the closest date.
The position of the cursor is unchanged if it is already on a date.
Returns the list (month day year) giving the cursor position."
(let ((date (calendar-cursor-to-date))
(column (current-column)))
(if date
date
(if (> 3 (count-lines (point-min) (point)))
(progn
(goto-line 3)
(move-to-column column)))
(if (not (looking-at "[0-9]"))
(if (and (not (looking-at " *$"))
(or (< column 25)
(and (> column 27)
(< column 50))
(and (> column 52)
(< column 75))))
(progn
(re-search-forward "[0-9]" nil t)
(backward-char 1))
(re-search-backward "[0-9]" nil t)))
(calendar-cursor-to-date))))
(defun calendar-forward-day (arg)
"Move the cursor forward ARG days.
Moves backward if ARG is negative."
(interactive "p")
(if (/= 0 arg)
(let*
((cursor-date (calendar-cursor-to-date))
(cursor-date (if cursor-date
cursor-date
(setq arg (if (< arg 0) (1+ arg) (1- arg)))
(calendar-cursor-to-nearest-date)))
(new-cursor-date
(calendar-gregorian-from-absolute
(+ (calendar-absolute-from-gregorian cursor-date) arg)))
(new-display-month (extract-calendar-month new-cursor-date))
(new-display-year (extract-calendar-year new-cursor-date)))
;; Put the new month on the screen, if needed, and go to the new date.
(if (not (calendar-date-is-visible-p new-cursor-date))
(calendar-other-month new-display-month new-display-year))
(calendar-cursor-to-visible-date new-cursor-date))))
(defun calendar-backward-day (arg)
"Move the cursor back ARG days.
Moves forward if ARG is negative."
(interactive "p")
(calendar-forward-day (- arg)))
(defun calendar-forward-week (arg)
"Move the cursor forward ARG weeks.
Moves backward if ARG is negative."
(interactive "p")
(calendar-forward-day (* arg 7)))
(defun calendar-backward-week (arg)
"Move the cursor back ARG weeks.
Moves forward if ARG is negative."
(interactive "p")
(calendar-forward-day (* arg -7)))
(defun calendar-beginning-of-week (arg)
"Move the cursor back ARG Sundays."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let ((day (calendar-day-of-week (calendar-cursor-to-date))))
(calendar-backward-day
(if (= day 0) (* 7 arg) (+ day (* 7 (1- arg)))))))
(defun calendar-end-of-week (arg)
"Move the cursor forward ARG Saturdays."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let ((day (calendar-day-of-week (calendar-cursor-to-date))))
(calendar-forward-day
(if (= day 6) (* 7 arg) (+ (- 6 day) (* 7 (1- arg)))))))
(defun calendar-beginning-of-month (arg)
"Move the cursor backward ARG month beginnings."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let* ((date (calendar-cursor-to-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date)))
(if (= day 1)
(calendar-backward-month arg)
(calendar-cursor-to-visible-date (list month 1 year))
(calendar-backward-month (1- arg)))))
(defun calendar-end-of-month (arg)
"Move the cursor forward ARG month ends."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let* ((date (calendar-cursor-to-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(last-day (calendar-last-day-of-month month year)))
(if (/= day last-day)
(progn
(calendar-cursor-to-visible-date (list month last-day year))
(setq arg (1- arg))))
(increment-calendar-month month year arg)
(let ((last-day (list
month
(calendar-last-day-of-month month year)
year)))
(if (not (calendar-date-is-visible-p last-day))
(calendar-other-month month year)
(calendar-cursor-to-visible-date last-day)))))
(defun calendar-beginning-of-year (arg)
"Move the cursor backward ARG year beginnings."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let* ((date (calendar-cursor-to-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(jan-first (list 1 1 year)))
(if (and (= day 1) (= 1 month))
(calendar-backward-month (* 12 arg))
(if (and (= arg 1)
(calendar-date-is-visible-p jan-first))
(calendar-cursor-to-visible-date jan-first)
(calendar-other-month 1 (- year (1- arg)))))))
(defun calendar-end-of-year (arg)
"Move the cursor forward ARG year beginnings."
(interactive "p")
(calendar-cursor-to-nearest-date)
(let* ((date (calendar-cursor-to-date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(year (extract-calendar-year date))
(dec-31 (list 12 31 year)))
(if (and (= day 31) (= 12 month))
(calendar-forward-month (* 12 arg))
(if (and (= arg 1)
(calendar-date-is-visible-p dec-31))
(calendar-cursor-to-visible-date dec-31)
(calendar-other-month 12 (- year (1- arg)))
(calendar-cursor-to-visible-date (list 12 31 displayed-year))))))
(defun extract-calendar-month (date)
"Extract the month part of DATE which has the form (month day year)."
(car date))
(defun extract-calendar-day (date)
"Extract the day part of DATE which has the form (month day year)."
(car (cdr date)))
(defun extract-calendar-year (date)
"Extract the year part of DATE which has the form (month day year)."
(car (cdr (cdr date))))
(defun calendar-gregorian-from-absolute (date)
"Compute the list (month day year) corresponding to the absolute DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let ((month 1)
(day 0)
(year (/ date 366)))
;; Calculate month, day, and year of DATE.
(while (< (calendar-absolute-from-gregorian (list 12 31 year)) date)
(setq year (1+ year)))
(while (< (calendar-absolute-from-gregorian
(list month (calendar-last-day-of-month month year) year))
date)
(setq month (1+ month)))
(setq day
(- (1+ date)
(calendar-absolute-from-gregorian (list month 1 year))))
(list month day year)))
(defun calendar-cursor-to-visible-date (date)
"Move the cursor to DATE that is on the screen."
(let ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date)))
(goto-line (+ 3
(/ (+ day -1
(calendar-day-of-week (list month 1 year)))
7)))
(move-to-column (+ 6
(* 25
(1+ (calendar-interval
displayed-month displayed-year month year)))
(* 3 (calendar-day-of-week date))))))
(defun calendar-other-month (month year)
"Display a three-month calendar centered around MONTH and YEAR."
(interactive "nMonth (1-12): \nnYear (>0): ")
(if (or (< 12 month) (> 1 month) (> 1 year))
(error "Unacceptable month/year!"))
(if (and (= month displayed-month)
(= year displayed-year))
nil
(let ((old-date (calendar-cursor-to-date))
(today (calendar-current-date)))
(regenerate-calendar-window
(calendar-interval current-month current-year month year))
(calendar-cursor-to-visible-date
(cond
((calendar-date-is-visible-p old-date) old-date)
((calendar-date-is-visible-p today) today)
(t (list month 1 year)))))))
(defun calendar-interval (mon1 yr1 mon2 yr2)
"The number of months difference between the two specified months."
(+ (* 12 (- yr2 yr1))
(- mon2 mon1)))
(defun calendar-leap-year-p (year)
"Returns t if YEAR is a Gregorian leap year, and false if not."
(or
(and (= (% year 4) 0)
(/= (% year 100) 0))
(= (% year 400) 0)))
(defun calendar-day-number (date)
"Return the day number within the year of the date DATE.
For example, (calendar-day-number (1 1 1987)) returns the value 1,
while (calendar-day-number (12 31 1980)) returns 366."
;;
;; An explanation of the calculation can be found in PascAlgorithms by
;; Edward and Ruth Reingold, Scott-Foresman/Little, Brown, 1988.
;;
(let* ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(day-of-year (+ day (* 31 (1- month)))))
(if (> month 2)
(progn
(setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
(if (calendar-leap-year-p year)
(setq day-of-year (1+ day-of-year)))))
day-of-year))
(defun calendar-day-name (date)
"Returns a string with the name of the day of the week of DATE."
(aref calendar-day-name-array (calendar-day-of-week date)))
(defconst calendar-day-name-array
["Sunday" "Monday" "Tuesday" "Wednesday" "Thursday" "Friday" "Saturday"])
(defun calendar-last-day-of-month (month year)
"The last day in MONTH during YEAR."
(if (and (calendar-leap-year-p year) (= month 2))
29
(aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
(defun calendar-month-name (month)
"The name of MONTH."
(aref ["January" "February" "March" "April" "May" "June"
"July" "August" "September" "October" "November" "December"]
(1- month)))
(defconst calendar-month-abbrev-list
'(("Jan" . 1) ("Feb" . 2) ("Mar" . 3) ("Apr" . 4)
("May" . 5) ("Jun" . 6) ("Jul" . 7) ("Aug" . 8)
("Sep" . 9) ("Oct" . 10) ("Nov" . 11) ("Dec" . 12)))
(defun calendar-day-of-week (date)
"Returns the day-of-the-week index of DATE, 0 for Sunday, 1 for Monday, etc."
(% (calendar-absolute-from-gregorian date) 7))
(defun calendar-absolute-from-gregorian (date)
"The number of days elapsed between the Gregorian date 12/31/1 BC and DATE.
The Gregorian date Sunday, December 31, 1 BC is imaginary."
(let ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date)))
(-
(+ (calendar-day-number date)
(* 365 (1- year))
(/ (1- year) 4))
(let ((correction (* (/ (1- year) 100) 3)))
(if (= (% correction 4) 0)
(/ correction 4)
(1+ (/ correction 4)))))))
(defun view-diary-entries (arg)
"Prepare and display a buffer with diary entries.
Searches the file diary-file for entries that match ARG days starting with
the date indicated by the cursor position in the displayed three-month
calendar."
(interactive "p")
(if (and diary-file (file-exists-p diary-file))
(list-diary-entries (or (calendar-cursor-to-date)
(error "Cursor is not on a date!"))
arg)
(error "You don't have a diary file!")))
(defun list-diary-entries (date number)
"Create and display a buffer containing the relevant lines in diary-file.
All lines that apply to DATE and the next NUMBER-1 days are included.
Returns a list of all relevant diary entries found, if any, in order by date.
The list entries have the form ((month day year) string). Also prepared is a
list of holidays for DATE, if `holidays-in-diary-buffer' is t. After the lists
is prepared, the hooks `list-diary-entries-hook' are run."
(if (< 0 number)
(let* ((diary-entries-list)
(holiday-list (if holidays-in-diary-buffer
(check-calendar-holidays date)))
(holiday-string "")
(h-list holiday-list)
(junk
(while h-list
(setq holiday-string
(concat holiday-string
(car h-list)
(if (cdr h-list) "; " "")))
(setq h-list (cdr h-list))))
(date-string (calendar-date-string date))
(month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date)))
(save-excursion
(let ((diary-buffer (get-file-buffer diary-file)))
(set-buffer (if diary-buffer
diary-buffer
(find-file-noselect diary-file t))))
(setq selective-display t)
(setq selective-display-ellipses nil)
(make-local-variable 'mode-line-format)
(setq mode-line-format
(concat "%*--"
(if (string-equal holiday-string "")
"---------------"
"")
"Diary "
(if (string-equal holiday-string "")
"entries for "
"for ")
date-string
(if (string-equal holiday-string "")
""
": ")
holiday-string
"%-"))
(let ((diary-modified (buffer-modified-p)))
(goto-char (1- (point-max)))
(if (not (looking-at "\^M\\|\n"))
(progn
(forward-char 1)
(insert-string "\^M")))
(goto-char (point-min))
(if (not (looking-at "\^M\\|\n"))
(insert-string "\^M"))
(subst-char-in-region (point-min) (point-max) ?\n ?\^M t)
(calendar-for-loop i from 1 to number do
(goto-char (point-min))
(let* ((mark (regexp-quote diary-nonmarking-symbol))
(regexp
(concat
"\\(\\`\\|\^M\\)\\("
"\\(" mark "?0*"
(int-to-string day) "[^0-9/]\\)"
"\\|\\(" mark "?0*" (int-to-string month)
"/0*" (int-to-string day) "[^0-9/]\\)"
"\\|\\(" mark "?0*" (int-to-string month)
"/0*" (int-to-string day)
"/0*" (int-to-string year) "[^0-9/]\\)"
"\\|\\(" mark "?"
(substring (calendar-month-name month) 0 3)
"\\(" (substring (calendar-month-name month) 3)
"\\|\\.?\\) +0*" (int-to-string day)
"\\(, *0*" (int-to-string year) "\\)?[^0-9]\\)"
"\\|\\(" mark "?\\* +0*"
(int-to-string day) "[^0-9]\\)"
"\\|" mark "?"
(calendar-day-name date) "[^a-z]"
"\\|" mark "?"
(substring (calendar-day-name date) 0 3) "[^a-z]"
"\\)"))
(case-fold-search t))
(while (re-search-forward regexp nil t)
(if (and (char-equal (preceding-char) ?\^M)
(not (looking-at " \\|\^I")))
nil;; Empty diary entry that consists only of the date.
;; Found a nonempty diary entry--make it visible and add
;; it to the list.
(let ((entry-start (point))
(date-start))
(re-search-backward "\^M\\|\n\\|\\`")
(setq date-start (point))
(re-search-forward "\^M\\|\n" nil t 2)
(while (looking-at " \\|\^I")
(re-search-forward "\^M\\|\n" nil t))
(backward-char 1)
(subst-char-in-region date-start (point) ?\^M ?\n t)
(setq diary-entries-list
(append
diary-entries-list
(list
(list date
(buffer-substring
entry-start
(point)))))))))
(setq date
(calendar-gregorian-from-absolute
(1+ (calendar-absolute-from-gregorian date))))
(setq month (extract-calendar-month date))
(setq day (extract-calendar-day date))
(setq year (extract-calendar-year date))))
(set-buffer-modified-p diary-modified))
(goto-char (point-min))
(run-hooks 'list-diary-entries-hook)
diary-entries-list))))
(defun prepare-fancy-diary-buffer ()
"Prepare a diary buffer with relevant entries in a fancy, noneditable form.
This function is provided for optional use as the `list-diary-entries-hook'."
(if (not diary-entries-list)
(message "No diary entries for %s %s" date-string holiday-string)
(save-excursion;; Turn off selective-display in the diary file's buffer.
(set-buffer (get-file-buffer diary-file))
(let ((diary-modified (buffer-modified-p)))
(subst-char-in-region (point-min) (point-max) ?\^M ?\n t)
(setq selective-display nil)
(kill-local-variable 'mode-line-format)
(set-buffer-modified-p diary-modified)))
(save-excursion;; Prepare the fancy diary buffer.
(set-buffer (get-buffer-create fancy-diary-buffer))
(setq buffer-read-only nil)
(make-local-variable 'mode-line-format)
(setq mode-line-format "---------------------------Diary Entries%-")
(erase-buffer)
(let ((entry-list diary-entries-list)
(date (list 0 0 0)))
(while entry-list
(if (not (calendar-date-equal date (car (car entry-list))))
(progn
(setq date (car (car entry-list)))
(let ((date-string (calendar-date-string date))
(holidays holiday-list))
(insert (if (= (point) (point-min)) "" ?\n) date-string)
(if holidays (insert ": " holiday-string))
(let ((l (current-column)))
(insert ?\n (make-string l ?=) ?\n)))))
(insert (car (cdr (car entry-list))) ?\n)
(setq entry-list (cdr entry-list))))
(set-buffer-modified-p nil)
(goto-char (point-min))
(setq buffer-read-only t)
(display-buffer fancy-diary-buffer))))
(defun print-diary-entries ()
"Print a hard copy of the entries visible in the diary window.
The hooks given by the variable `print-diary-entries-hook' are called after
the temporary buffer of visible diary entries is prepared; it is the hooks
that do the actual printing and kill the buffer."
(interactive)
(let ((diary-buffer (get-file-buffer diary-file)))
(if diary-buffer
(let ((temp-buffer (get-buffer-create "*Printable Diary Entries*")))
(save-excursion
(set-buffer diary-buffer)
(copy-to-buffer temp-buffer (point-min) (point-max))
(set-buffer temp-buffer)
(while (re-search-forward "\^M.*$" nil t)
(replace-match ""))
(run-hooks 'print-diary-entries-hook)))
(error "You don't have a diary buffer!"))))
(defun add-diary-heading ()
"Add a heading to the diary entries for printing.
The heading is formed from the mode line of the diary buffer. This function
is used in the default value of the variable `print-diary-entry-hooks'."
(save-excursion
(let ((heading))
(set-buffer diary-buffer)
(setq heading mode-line-format)
(string-match "%\\*-*\\([^-].*\\)%-$" heading)
(setq heading
(substring heading (match-beginning 1) (match-end 1)))
(set-buffer temp-buffer)
(goto-char (point-min))
(insert heading "\n"
(make-string (length heading) ?=) "\n"))))
(defun show-all-diary-entries ()
"Show all of the diary entries in the diary-file.
This function gets rid of the selective display of the diary-file so that
all entries, not just some, are visible. If there is no diary buffer, one
is created."
(interactive)
(if (and diary-file (file-exists-p diary-file))
(save-excursion
(let ((diary-buffer (get-file-buffer diary-file)))
(set-buffer (if diary-buffer
diary-buffer
(find-file-noselect diary-file t)))
(let ((diary-modified (buffer-modified-p)))
(subst-char-in-region (point-min) (point-max) ?\^M ?\n t)
(setq selective-display nil)
(make-local-variable 'mode-line-format)
(setq mode-line-format
(concat "%*---------------------------All Diary Entries%-"))
(display-buffer (current-buffer))
(set-buffer-modified-p diary-modified))))
(error "You don't have a diary file!")))
(defun mark-diary-entries ()
"Mark days in the calendar window that have diary entries.
Each entry in diary-file visible in the calendar window is marked."
(interactive)
(if (and diary-file (file-exists-p diary-file))
(save-excursion
(message "Marking diary entries...")
(set-buffer (find-file-noselect diary-file t))
(let ((case-fold-search t)
(dayname))
;; For each marking DAYNAME entry in the diary-file,
;; mark dates with that name.
(calendar-for-loop day from 0 to 6 do
(setq dayname (aref calendar-day-name-array day))
(goto-char (point-min))
(if (re-search-forward
(concat "\\(^\\|\^M\\)" (substring dayname 0 3)
"\\(" (substring dayname 3) "\\)?[^a-z]")
nil t)
(mark-calendar-days-named day)))
;; For each marking entry in the diary-file,
;; mark it if it is in range.
(goto-char (point-min))
(while
(re-search-forward "\\(^\\|\^M\\)\\([0-9]+\\|[*.a-z]+\\)[^0-9]"
nil t)
(let ((month (buffer-substring (match-beginning 2) (match-end 2)))
(named-month t)
(day 0)
(year 0))
(if (string-equal "*" (substring month 0 1))
(setq month 0)
(let ((value (string-to-int month)))
(if (= value 0)
(setq month
(cdr (assoc
(if (< 2 (length month))
(capitalize
(substring month 0 3)))
calendar-month-abbrev-list)))
(setq month value)
(setq named-month nil))))
(if month;; Not nil means it was found.
(progn
(backward-char 1)
(if (or named-month (looking-at "/"))
(progn
(re-search-forward
"\\( \\|/\\)\\([0-9]+\\)[^0-9]" nil t)
(setq day (string-to-int
(buffer-substring (match-beginning 2)
(match-end 2)))))
(setq day month);; It's a DAY entry, not a MONTH.
(setq month 0)
(forward-char 1))
(backward-char 1)
(if (or (looking-at "/")
(and named-month (looking-at ",")))
(progn
(re-search-forward
"\\(, +\\|/\\)\\([0-9]+\\)[^0-9]" nil t)
(setq year (string-to-int
(buffer-substring (match-beginning 2)
(match-end 2))))))
(mark-calendar-date-pattern month day year))))))
(message "Marking diary entries...done"))
(error "You don't have a diary file!")))
(defun mark-calendar-days-named (dayname)
"Mark all dates in the calendar window that are day DAYNAME of the week.
0 means all Sundays, 1 means all Mondays, and so on."
(save-excursion
(set-buffer calendar-buffer)
(let ((prev-month displayed-month)
(prev-year displayed-year)
(succ-month displayed-month)
(succ-year displayed-year)
(last-day)
(day))
(increment-calendar-month succ-month succ-year 1)
(increment-calendar-month prev-month prev-year -1)
(setq day (calendar-absolute-from-gregorian
(calendar-nth-named-day dayname 1 prev-month prev-year)))
(setq last-day (calendar-absolute-from-gregorian
(calendar-nth-named-day dayname 5 succ-month succ-year)))
(while (<= day last-day)
(mark-visible-calendar-date (calendar-gregorian-from-absolute day))
(setq day (+ day 7))))))
(defun mark-calendar-date-pattern (month day year)
"Mark all dates in the calendar window that conform to MONTH/DAY/YEAR.
A value of 0 is a wild-card. Either only the year is 0 or both the month
and the year are 0; the month alone cannot be 0."
(save-excursion
(set-buffer calendar-buffer)
(let ((prev-month displayed-month)
(prev-year displayed-year)
(succ-month displayed-month)
(succ-year displayed-year))
(increment-calendar-month succ-month succ-year 1)
(increment-calendar-month prev-month prev-year -1)
(if (or (and (= month prev-month)
(or (= year 0) (= year prev-year)))
(= month 0))
(mark-visible-calendar-date (list prev-month day prev-year)))
(if (or (and (= month displayed-month)
(or (= year 0) (= year displayed-year)))
(= month 0))
(mark-visible-calendar-date
(list displayed-month day displayed-year)))
(if (or (and (= month succ-month)
(or (= year 0) (= year succ-year)))
(= month 0))
(mark-visible-calendar-date (list succ-month day succ-year))))))
(defun calendar-unmark ()
"Delete the diary and holiday marks from the calendar."
(interactive)
(let ((buffer-read-only nil)
(marker (concat (regexp-quote diary-entry-marker)
"\\|"
(regexp-quote calendar-holiday-marker))))
(save-excursion
(goto-line 3)
(while (re-search-forward marker nil t)
(delete-char -1)
(insert " "))
(set-buffer-modified-p nil))))
(defun calendar-date-is-visible-p (date)
"Returns t if DATE is legal and is visible in the calendar window."
(save-excursion
(if (bufferp calendar-buffer) (set-buffer calendar-buffer))
(let ((gap (calendar-interval
displayed-month displayed-year
(extract-calendar-month date) (extract-calendar-year date))))
(and (calendar-date-is-legal-p date) (> 2 gap) (< -2 gap)))))
(defun calendar-date-is-legal-p (date)
"Returns t if DATE is a legal date."
(let ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date)))
(and (<= 1 month) (<= month 12)
(<= 1 day) (<= day (calendar-last-day-of-month month year))
(<= 1 year))))
(defun calendar-date-equal (date1 date2)
"Returns t if the DATE1 and DATE2 are the same."
(and
(= (extract-calendar-month date1) (extract-calendar-month date2))
(= (extract-calendar-day date1) (extract-calendar-day date2))
(= (extract-calendar-year date1) (extract-calendar-year date2))))
(defun mark-visible-calendar-date (date &optional mark)
"Leave mark DATE with MARK. MARK defaults to diary-entry-marker."
(if (calendar-date-is-legal-p date)
(save-excursion
(set-buffer calendar-buffer)
(calendar-cursor-to-visible-date date)
(forward-char 1)
(let ((buffer-read-only nil))
(delete-char 1)
(insert (if mark mark diary-entry-marker))
(forward-char -2))
(set-buffer-modified-p nil))))
(defun calendar-nth-named-day (dayname n month year)
"Returns the date of the Nth DAYNAME in MONTH, YEAR.
A DAYNAME of 0 means Sunday, 1 means Monday, and so on. If N>4, the
date returned is the last DAYNAME in MONTH, YEAR."
(let* ((first-day-name (calendar-day-of-week (list month 1 year)))
(day (1+ (- dayname first-day-name))))
(if (<= day 0)
(setq day (+ day 7)))
;; Day is now the first DAYNAME in the month.
(setq day (+ day (* 7 (1- n))))
(while (> day (calendar-last-day-of-month month year))
(setq day (- day 7)))
(list month day year)))
(defun calendar-star-date ()
"Replace the date under the cursor in the calendar window with asterisks.
This function can be used with the today-visible-calendar-hook run after the
calendar window has been prepared."
(let ((buffer-read-only nil))
(forward-char 1)
(delete-char -2)
(insert "**")
(backward-char 1)
(set-buffer-modified-p nil)))
(defun calendar-mark-today ()
"Mark the date under the cursor in the calendar window with an asterisk.
This function can be used with the today-visible-calendar-hook run after the
calendar window has been prepared."
(let ((buffer-read-only nil))
(forward-char 1)
(delete-char 1)
(insert "*")
(backward-char 2)
(set-buffer-modified-p nil)))
(defun calendar-fixed-day (month day string)
"Returns the exact date, if visible in the window.
If it is visible, the value returned is the list ((MONTH DAY year) STRING).
Returns nil if it is not visible in the current calendar window."
(let ((m displayed-month)
(y displayed-year))
(increment-calendar-month m y (- 11 month))
(if (> m 9)
(list (list month day y) string))))
(defun calendar-float-day (month dayname n string)
"Returns date of the n-th occurence of day named, if visible in the window.
If it is visible, a list is returned consisting of the date in MONTH of the
day DAYNAME's N-th appearance, followed by STRING. Returns nil if it
is not visible in the current calendar window. If it is visible, the value
returned is ((MONTH day year) STRING), where (MONTH day year) is the N-th
DAYNAME of MONTH. If N>4, the last occurence is returned."
(let ((m displayed-month)
(y displayed-year))
(increment-calendar-month m y (- 11 month))
(if (> m 9)
(list (calendar-nth-named-day dayname n month y) string))))
(defun check-calendar-holidays (date)
"Check the list of holidays for any that occur on DATE.
The value returned is a list of strings of relevant holiday descriptions.
The holidays are those in the list calendar-holidays."
(let* ((p calendar-holidays)
(holiday)
(holiday-list)
(a-date (calendar-absolute-from-gregorian date))
(h-date (calendar-hebrew-from-absolute a-date))
(h-month (extract-calendar-month h-date))
(h-day (extract-calendar-day h-date))
(i-date (calendar-islamic-from-absolute a-date))
(i-month (extract-calendar-month i-date))
(i-day (extract-calendar-day i-date))
(j-date (calendar-julian-from-absolute a-date))
(j-month (extract-calendar-month j-date))
(j-day (extract-calendar-day j-date))
(m (extract-calendar-month date))
(y (extract-calendar-year date)))
(while p
(cond
((equal (car (car p)) 'fixed)
(setq holiday
(if (calendar-date-equal
date
(list (car (nthcdr 1 (car p)))
(car (nthcdr 2 (car p)))
y))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'float)
(setq holiday
(if (calendar-date-equal
date
(calendar-nth-named-day
(car (nthcdr 2 (car p)))
(car (nthcdr 3 (car p)))
(car (nthcdr 1 (car p)))
y))
(car (nthcdr 4 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'hebrew)
(setq holiday
(if (and
(= h-month (car (nthcdr 1 (car p))))
(= h-day (car (nthcdr 2 (car p)))))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'islamic)
(setq holiday
(if (and
(= i-month (car (nthcdr 1 (car p))))
(= i-day (car (nthcdr 2 (car p)))))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'julian)
(setq holiday
(if (and
(= j-month (car (nthcdr 1 (car p))))
(= j-day (car (nthcdr 2 (car p)))))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'special)
(let* ((displayed-month m)
(displayed-year y)
(h-list (funcall (car (nthcdr 1 (car p))))))
(while h-list
(if (calendar-date-equal
date
(car (car h-list)))
(setq holiday-list (append holiday-list (cdr (car h-list)))))
(setq h-list (cdr h-list))))))
(setq p (cdr p)))
holiday-list))
(defun calendar-cursor-holidays ()
"Find holidays for the date specified by the cursor in the calendar window."
(interactive)
(let* ((date (calendar-cursor-to-date))
(d-string (calendar-date-string date))
(h-list (check-calendar-holidays date))
(h-string ""))
(while h-list
(setq h-string
(concat h-string
(car h-list)
(if (cdr h-list) "; " "")))
(setq h-list (cdr h-list)))
(if (string-equal h-string "")
(message "No holidays known for %s" d-string)
(message "%s: %s" d-string h-string))))
(defun calendar-holiday-list ()
"Form the list of holidays that occur on dates in the calendar window.
The holidays are those in the list calendar-holidays. If the calendar window
hasn't changed, use the old list, if it exists."
(if displayed-calendar-holiday-list
displayed-calendar-holiday-list
(let ((p calendar-holidays)
(holiday)
(holiday-list))
(while p
(cond
((equal (car (car p)) 'fixed)
(setq holiday (calendar-fixed-day
(car (nthcdr 1 (car p)))
(car (nthcdr 2 (car p)))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'float)
(setq holiday (calendar-float-day
(car (nthcdr 1 (car p)))
(car (nthcdr 2 (car p)))
(car (nthcdr 3 (car p)))
(car (nthcdr 4 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'hebrew)
(setq holiday (hebrew-calendar-date
(car (nthcdr 1 (car p)))
(car (nthcdr 2 (car p)))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'islamic)
(setq holiday (islamic-calendar-date
(car (nthcdr 1 (car p)))
(car (nthcdr 2 (car p)))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'julian)
(setq holiday (julian-calendar-date
(car (nthcdr 1 (car p)))
(car (nthcdr 2 (car p)))
(car (nthcdr 3 (car p)))))
(if holiday
(setq holiday-list (cons holiday holiday-list))))
((equal (car (car p)) 'special)
(setq holiday (funcall (car (nthcdr 1 (car p)))))
(if holiday
(setq holiday-list (append holiday holiday-list)))))
(setq p (cdr p)))
(setq displayed-calendar-holiday-list
(sort holiday-list 'calendar-list-compare)))))
(defun mark-calendar-holidays ()
"Mark notable days in the calendar window."
(interactive)
(message "Marking holidays...")
(let ((holiday-list (calendar-holiday-list)))
(while holiday-list
(mark-visible-calendar-date
(car (car holiday-list)) calendar-holiday-marker)
(setq holiday-list (cdr holiday-list))))
(message "Marking holidays...done"))
(defun list-calendar-holidays ()
"Create a buffer containing the holidays for the current calendar window.
The holidays are those in the list calendar-notable-days. Returns t if any
holidays are found, nil if not."
(interactive)
(message "Looking up holidays...")
(let ((holiday-list (calendar-holiday-list))
(m1 displayed-month)
(y1 displayed-year)
(m2 displayed-month)
(y2 displayed-year))
(if (not holiday-list)
(progn
(message "Looking up holidays...none found")
nil)
(set-buffer (get-buffer-create holiday-buffer))
(setq buffer-read-only nil)
(increment-calendar-month m1 y1 -1)
(increment-calendar-month m2 y2 1)
(setq mode-line-format
(concat "-------------Notable Dates from "
(calendar-month-name m1) ", "
(int-to-string y1) " to "
(calendar-month-name m2) ", "
(int-to-string y2)
"%-"))
(erase-buffer)
(while holiday-list
(insert-string (calendar-date-string (car (car holiday-list))))
(insert-string ": ")
(insert-string (car (cdr (car holiday-list))))
(insert-string "\n")
(setq holiday-list (cdr holiday-list)))
(goto-char (point-min))
(set-buffer-modified-p nil)
(setq buffer-read-only t)
(display-buffer holiday-buffer)
(message "Looking up holidays...done")
t)))
(defun calendar-list-compare (date1 date2)
"Returns t if DATE1 is before DATE2, nil otherwise.
The actual dates are in the car of DATE1 and DATE2."
(< (calendar-absolute-from-gregorian (car date1))
(calendar-absolute-from-gregorian (car date2))))
(defun calendar-date-string (date)
"A string form of DATE."
(concat
(calendar-day-name date) ", "
(calendar-month-name (extract-calendar-month date)) " "
(int-to-string (extract-calendar-day date)) ", "
(int-to-string (extract-calendar-year date))))
(defun calendar-easter-etc ()
"List of dates related to Easter, as visible in calendar window."
;; The algorithm is from pages 155-156 of The Art of Computer Programming,
;; Volume 1, second edition, by Donald E. Knuth.
(if (> displayed-month 5)
nil;; Ash Wednesday, Good Friday, and Easter are not visible.
(let* ((c (1+ (/ displayed-year 100)));; century
(g (1+ (% displayed-year 19)));; golden number
(x (- (/ (* 3 c) 4) 12));; number of non-leap year century years
(z (- (/ (+ (* 8 c) 5) 25) 5));; lunar correction
(d (- (/ (* 5 displayed-year) 4) x 10));; sunday
(e (+ (* 11 g) 20 z (- x)));; epact (full moon)
(e (if (< e 0)
(% (+ e 30) 30)
(% e 30)))
(e (if (or (and (= e 25) (> g 11))
(= e 24))
(1+ e)
e))
(n (- 44 e));; n-th of March is a full moon.
(n (if (< n 21)
(+ n 30)
n))
(n (+ n 7 (- (% (+ d n) 7))));; the next Sunday
(easter
(if (> n 31)
(list 4 (- n 31) displayed-year)
(list 3 n displayed-year)))
(abs-easter (calendar-absolute-from-gregorian easter))
(good-friday (calendar-gregorian-from-absolute (- abs-easter 2)))
(ash-weds (calendar-gregorian-from-absolute (- abs-easter 46)))
(output-list))
(if (calendar-date-is-visible-p ash-weds)
(setq output-list (list (list ash-weds "Ash Wednesday"))))
(if (calendar-date-is-visible-p good-friday)
(setq output-list
(append (list (list good-friday "Good Friday")) output-list)))
(if (calendar-date-is-visible-p easter)
(setq output-list
(append (list (list easter "Easter Sunday")) output-list)))
output-list)))
(defun calendar-julian-from-absolute (date)
"Compute the Julian (month day year) corresponding to the absolute DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let ((month 1)
(day 0)
(year (/ date 366)))
;; Calculate month, day, and year of DATE.
(while (< (calendar-absolute-from-julian (list 12 31 year)) date)
(setq year (1+ year)))
(while (< (calendar-absolute-from-julian
(list month
(if (and (= month 2) (= (% year 4) 0))
29
(aref [31 28 31 30 31 30 31 31 30 31 30 31]
(1- month)))
year))
date)
(setq month (1+ month)))
(setq day
(- (1+ date)
(calendar-absolute-from-julian (list month 1 year))))
(list month day year)))
(defun calendar-absolute-from-julian (date)
"The number of days elapsed between the Gregorian date 12/31/1 BC and DATE.
The Gregorian date Sunday, December 31, 1 BC is imaginary."
(let ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date)))
(+ (calendar-day-number date)
(if (and (= (% year 100) 0)
(/= (% year 400) 0)
(> month 2))
1 0);; Correct for Julian but not Gregorian leap year.
(* 365 (1- year))
(/ (1- year) 4)
-2)))
(defun cursor-to-julian-calendar-date ()
"Show the Julian calendar equivalent of the date under the cursor."
(interactive)
(let* ((julian-date (calendar-julian-from-absolute
(calendar-absolute-from-gregorian
(or (calendar-cursor-to-date)
(error "Cursor is not on a date!")))))
(month (extract-calendar-month julian-date))
(day (extract-calendar-day julian-date))
(year (extract-calendar-year julian-date)))
(message "Julian date: %s %d, %d"
(calendar-month-name month)
day year)))
(defun julian-calendar-date (month day string)
"Returns the corresponding Gregorian date, if visible in the window.
If it is visible, the value returned is the list ((MONTH DAY year) STRING).
Returns nil if it is not visible in the current calendar window."
(let ((m1 displayed-month)
(y1 displayed-year)
(m2 displayed-month)
(y2 displayed-year)
(year))
(increment-calendar-month m1 y1 -1)
(increment-calendar-month m2 y2 1)
(let* ((start-date (calendar-absolute-from-gregorian
(list m1 1 y1)))
(end-date (calendar-absolute-from-gregorian
(list m2 (calendar-last-day-of-month m2 y2) y2)))
(julian-start (calendar-julian-from-absolute start-date))
(julian-end (calendar-julian-from-absolute end-date))
(julian-y1 (extract-calendar-year julian-start))
(julian-y2 (extract-calendar-year julian-end)))
(setq year (if (< 10 month) julian-y1 julian-y2))
(let ((date (calendar-gregorian-from-absolute
(calendar-absolute-from-julian
(list month day year)))))
(if (calendar-date-is-visible-p date)
(list date string))))))
(defun islamic-calendar-leap-year-p (year)
"Returns t if YEAR is a leap year on the Islamic calendar."
(memq (% year 30)
(list 2 5 7 10 13 16 18 21 24 26 29)))
(defun islamic-calendar-last-day-of-month (month year)
"The last day in MONTH during YEAR on the Islamic calendar."
(cond
((memq month (list 1 3 5 7 9 11)) 30)
((memq month (list 2 4 6 8 10)) 29)
(t (if (islamic-calendar-leap-year-p year) 30 29))))
(defun islamic-calendar-day-number (date)
"Return the day number within the year of the Islamic date DATE."
(let* ((month (extract-calendar-month date))
(day (extract-calendar-day date)))
(+ (* 30 (/ month 2))
(* 29 (/ (1- month) 2))
day)))
(defun calendar-absolute-from-islamic (date)
"Absolute date of Islamic DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let* ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (extract-calendar-year date))
(y (% year 30))
(leap-years-in-cycle
(cond
((< y 3) 0) ((< y 6) 1) ((< y 8) 2) ((< y 11) 3) ((< y 14) 4)
((< y 17) 5) ((< y 19) 6) ((< y 22) 7) ((< y 25) 8) ((< y 27) 9)
(t 10))))
(+ (islamic-calendar-day-number date);; days so far this year
(* (1- year) 354) ;; days in all non-leap years
(* 11 (/ year 30)) ;; leap days in complete cycles
leap-years-in-cycle ;; leap days this cycle
227014))) ;; days before start of calendar
(defun calendar-islamic-from-absolute (date)
"Compute the Islamic date (month day year) corresponding to absolute DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let* ((month 1)
(day 1)
(year (/ (- date 227014) 355)))
(if (< year 0)
(list 0 0 0)
(while (> date
(calendar-absolute-from-islamic
(list 12 (islamic-calendar-last-day-of-month 12 year) year)))
(setq year (1+ year)))
(while (> date
(calendar-absolute-from-islamic
(list month
(islamic-calendar-last-day-of-month month year)
year)))
(setq month (1+ month)))
(setq day
(1+ (- date (calendar-absolute-from-islamic (list month 1 year)))))
(list month day year))))
(defun cursor-to-islamic-calendar-date ()
"Show the Islamic calendar equivalent of the date under the cursor."
(interactive)
(let* ((islamic-date (calendar-islamic-from-absolute
(calendar-absolute-from-gregorian
(or (calendar-cursor-to-date)
(error "Cursor is not on a date!")))))
(month (extract-calendar-month islamic-date))
(day (extract-calendar-day islamic-date))
(year (extract-calendar-year islamic-date)))
(if (< year 1)
(message "Date is pre-Islamic")
(message "Islamic date: %s %d, %d"
(aref ["Muharram" "Safar" "Rabi I" "Rabi II" "Jumada I"
"Jumada II" "Rajab" "Sha'ban" "Ramadan" "Shawwal"
"Dhu al-Qada" "Dhu al-Hijjah"]
(1- month))
day year))))
(defun islamic-calendar-date (month day string)
"Returns the corresponding Gregorian date, if visible in the window.
If it is visible, the value returned is the list ((MONTH DAY year) STRING).
If the specified date is the Islamic new year (MONTH=DAY=1), the number of the
year is appended to STRING. Returns nil if Islamic MONTH, DAY is not visible
in the current calendar window."
(let* ((islamic-date (calendar-islamic-from-absolute
(calendar-absolute-from-gregorian
(list displayed-month 15 displayed-year))))
(m (extract-calendar-month islamic-date))
(y (extract-calendar-year islamic-date))
(date))
(if (< m 1)
nil;; Islamic calendar doesn't apply.
(increment-calendar-month m y (- 10 month))
(if (> m 7);; (MONTH, DAY, y) might be visible
(let ((date (calendar-gregorian-from-absolute
(calendar-absolute-from-islamic (list month day y)))))
(if (calendar-date-is-visible-p date)
(list date
(if (and (= month 1) (= day 1))
(concat string " " (int-to-string y))
string))))))))
(defun cursor-to-hebrew-calendar-date ()
"Show the Hebrew calendar equivalent of the date under the cursor."
(interactive)
(message "Hebrew date: computing...")
(let* ((hebrew-date (calendar-hebrew-from-absolute
(calendar-absolute-from-gregorian
(or (calendar-cursor-to-date)
(error "Cursor is not on a date!")))))
(m (extract-calendar-month hebrew-date))
(d (extract-calendar-day hebrew-date))
(y (extract-calendar-year hebrew-date)))
(message "Hebrew date: %s %d, %d"
(if (and (hebrew-calendar-leap-year-p (- y 3761)) (= m 12))
"Adar I"
(aref ["Nisan" "Iyar" "Sivan" "Tammuz" "Av" "Elul" "Tishri"
"Heshvan" "Kislev" "Teveth" "Shevat" "Adar" "Adar II"]
(1- m)))
d y)))
(defun calendar-rosh-hashanah-etc ()
"List of dates related to Rosh Hashanah, as visible in calendar window."
(if (or (< displayed-month 8)
(> displayed-month 11))
nil;; None of the dates are visible
(let* ((abs-r-h (hebrew-calendar-new-year-day displayed-year))
(rosh-h (calendar-gregorian-from-absolute abs-r-h))
(yom-k (calendar-gregorian-from-absolute (+ abs-r-h 9)))
(suc (calendar-gregorian-from-absolute (+ abs-r-h 14)))
(output-list))
(if (calendar-date-is-visible-p rosh-h)
(setq output-list
(list (list rosh-h
(concat "Rosh Hashanah "
(int-to-string
(+ 3761 displayed-year)))))))
(if (calendar-date-is-visible-p yom-k)
(setq output-list
(append (list (list yom-k "Yom Kippur")) output-list)))
(if (calendar-date-is-visible-p suc)
(setq output-list
(append (list (list suc "Succoth")) output-list)))
output-list)))
(defun hebrew-calendar-date (month day string)
"Returns the corresponding Gregorian date, if visible in the window.
If it is visible, the value returned is the list ((MONTH DAY year) STRING).
Returns nil if it is not visible in the current calendar window."
(if (memq displayed-month;; This test is only to speed things up a bit;
(list ;; it works fine without the test too.
(if (< 11 month) (- month 11) (+ month 1))
(if (< 10 month) (- month 10) (+ month 2))
(if (< 9 month) (- month 9) (+ month 3))
(if (< 8 month) (- month 8) (+ month 4))))
(let ((m1 displayed-month)
(y1 displayed-year)
(m2 displayed-month)
(y2 displayed-year)
(year))
(increment-calendar-month m1 y1 -1)
(increment-calendar-month m2 y2 1)
(let* ((start-date (calendar-absolute-from-gregorian
(list m1 1 y1)))
(end-date (calendar-absolute-from-gregorian
(list m2 (calendar-last-day-of-month m2 y2) y2)))
(hebrew-start (calendar-hebrew-from-absolute start-date))
(hebrew-end (calendar-hebrew-from-absolute end-date))
(hebrew-y1 (extract-calendar-year hebrew-start))
(hebrew-y2 (extract-calendar-year hebrew-end)))
(setq year (if (< 6 month) hebrew-y2 hebrew-y1))
(let ((date (calendar-gregorian-from-absolute
(calendar-absolute-from-hebrew
(list month day year)))))
(if (calendar-date-is-visible-p date)
(list date string)))))))
(defun calendar-hebrew-from-absolute (date)
"Compute the Hebrew date (month day year) corresponding to absolute DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let* ((greg-date (calendar-gregorian-from-absolute date))
(month (aref [9 10 11 12 1 2 3 4 7 7 7 8]
(1- (extract-calendar-month greg-date))))
(day)
(year (+ 3760 (extract-calendar-year greg-date))))
(while (> date (calendar-absolute-from-hebrew (list 6 29 year)))
(setq year (1+ year)))
(let ((length (hebrew-calendar-last-month-of-year (- year 3761))))
(while (> date
(calendar-absolute-from-hebrew
(list month
(hebrew-calendar-last-day-of-month month (- year 3761))
year)))
(setq month (1+ (% month length)))))
(setq day (1+
(- date (calendar-absolute-from-hebrew (list month 1 year)))))
(list month day year)))
;; The functions from here on were written by Nachum Dershowitz in Common Lisp
;; and rewritten in Emacs Lisp by E.M.R. The Hebrew months are numbered from
;; 1 through 13, starting with Nisan and ending with Adar II; in this scheme,
;; Tishri is the seventh month, just as in the Bible.
(defconst hebrew-calendar-epoch (list 247 20 785)
"Extrapolated new moon for year 0 Gregorian.")
(defconst hebrew-calendar-regular-year (list 354 8 876)
"Excess length of 12 (mean) lunations.")
(defconst hebrew-calendar-leap-year (list 383 21 589)
"Excess length of 13 lunations.")
(defconst hebrew-calendar-cycle (list 6939 16 595)
"Length of 235 lunations (19 year Metonic cycle).")
(defun extract-hebrew-calendar-days (interval)
"Extract the day part of INTERVAL which has the form (days hours parts)."
(car interval))
(defun extract-hebrew-calendar-hours (interval)
"Extract the hours part of INTERVAL which has the form (days hours parts)."
(car (cdr interval)))
(defun extract-hebrew-calendar-parts (interval)
"Extract the parts part of INTERVAL which has the form (days hours parts)."
(car (cdr (cdr interval))))
(defun normalize-hebrew-calendar-interval (interval)
"Returns a normalized version of INTERVAL.
Normalized in the sense that the number of hours is less than 24 and
the number of parts is less than 1080."
(let ((hours (+ (extract-hebrew-calendar-hours interval)
(/ (extract-hebrew-calendar-parts interval) 1080))))
(list (+ (extract-hebrew-calendar-days interval) (/ hours 24))
(% hours 24)
(% (extract-hebrew-calendar-parts interval) 1080))))
(defun add-hebrew-calendar-intervals (&rest l)
"Add the list L of intervals and normalize."
(let ((sum (list 0 0 0)))
(while (car l)
(setq sum
(list (+ (extract-hebrew-calendar-days (car l))
(extract-hebrew-calendar-days sum))
(+ (extract-hebrew-calendar-hours (car l))
(extract-hebrew-calendar-hours sum))
(+ (extract-hebrew-calendar-parts (car l))
(extract-hebrew-calendar-parts sum))))
(setq l (cdr l)))
(normalize-hebrew-calendar-interval sum)))
(defun multiply-hebrew-calendar-interval (interval c)
"Multiply INTERVAL by C."
(normalize-hebrew-calendar-interval
(list (* (extract-hebrew-calendar-days interval) c)
(* (extract-hebrew-calendar-hours interval) c)
(* (extract-hebrew-calendar-parts interval) c))))
(defun hebrew-calendar-cycles (year)
"Number of complete cycles before YEAR+3761."
(/ (1- year) 19))
(defun years-into-hebrew-calendar-cycle (year)
"Number of years prior to YEAR+3761 in the current cycle."
(% (1- year) 19))
(defun prior-leap-years-in-hebrew-calendar-cycle (year)
"Number of leap years prior to YEAR+3761 in the current cycle."
(let ((y (years-into-hebrew-calendar-cycle year)))
(cond ((>= y 18) 7) ((>= y 15) 6) ((>= y 12) 5)
((>= y 9) 4) ((>= y 7) 3) ((>= y 4) 2)
((>= y 1) 1) (t 0))))
(defun prior-regular-years-in-hebrew-calendar-cycle (year)
"Number of regular (non-leap) years prior to YEAR+3761 in the current cycle."
(- (years-into-hebrew-calendar-cycle year)
(prior-leap-years-in-hebrew-calendar-cycle year)))
(defun hebrew-calendar-new-year-mean-conjunction (year)
"The time of week of the mean conjunction of Tishri of YEAR+3761."
(let ((interval
(add-hebrew-calendar-intervals
hebrew-calendar-epoch
(multiply-hebrew-calendar-interval
hebrew-calendar-cycle
(hebrew-calendar-cycles year))
(multiply-hebrew-calendar-interval
hebrew-calendar-regular-year
(prior-regular-years-in-hebrew-calendar-cycle year))
(multiply-hebrew-calendar-interval
hebrew-calendar-leap-year
(prior-leap-years-in-hebr
uxc.cso.uiuc.edu ignored 42 excess bytesreingold@m.cs.uiuc.edu (04/04/89)
It was reported to me that the message was too big and the last few lines
were lost. A complete copy can be obtained by anonymous ftp from
a.cs.uiuc.edu. In any case, here are the last few lines. (There is
some overlap--check!)
----------------------------------------------------------------------
(defun hebrew-calendar-leap-year-p (year)
"Returns t if YEAR+3761 is a leap year."
(memq
(years-into-hebrew-calendar-cycle year)
(list 0 3 6 8 11 14 17)))
(defun hebrew-calendar-long-heshvan-p (year)
"Returns t if Heshvan is long in YEAR+3761."
(if (hebrew-calendar-leap-year-p year)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 385)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 355)))
(defun hebrew-calendar-short-kislev-p (year)
"Returns t if Kislev is short in YEAR+3761."
(if (hebrew-calendar-leap-year-p year)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 383)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 353)))
(defun hebrew-calendar-last-day-of-month (month year)
"The last day of MONTH in YEAR+3761."
(if (or (memq month (list 2 4 6 10 13))
(and (= month 12) (not (hebrew-calendar-leap-year-p year)))
(and (= month 8) (not (hebrew-calendar-long-heshvan-p year)))
(and (= month 9) (hebrew-calendar-short-kislev-p year)))
29
30))
(defun hebrew-calendar-date-beyond-date (days month year)
"Returns the Hebrew date that is DAYS beyond the start of MONTH, YEAR+3761.
That date must be in the same year."
(let ((len (hebrew-calendar-last-day-of-month month year)))
(while (> days len)
(setq days (- days len))
(setq month (1+ (% month (hebrew-calendar-last-month-of-year year))))
(setq len (hebrew-calendar-last-day-of-month month year))))
(list days month year))
(defun hebrew-calendar-days-from-tishri (days month year)
"Number of days, inclusive, from 1 Tishri to DAYS, MONTH, YEAR+3761."
(while (/= month 7)
(setq month
(if (= month 1)
(hebrew-calendar-last-month-of-year year)
(1- month)))
(setq days (+ days (hebrew-calendar-last-day-of-month month year))))
days)
(defun hebrew-calendar-year-length (year)
"The number of days in Hebrew calendar YEAR+3761."
(- (hebrew-calendar-new-year-day year)
(hebrew-calendar-new-year-day (1- year))))
(defun hebrew-calendar-last-month-of-year (year)
"The last month of the Hebrew calendar YEAR+3761."
(if (hebrew-calendar-leap-year-p year)
13
12))
(defun calendar-absolute-from-hebrew (date)
"Absolute date of Hebrew DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (- (extract-calendar-year date) 3761)))
(+
-1
(hebrew-calendar-new-year-day year)
(hebrew-calendar-days-from-tishri day month year))))jr@bbn.com (John Robinson) (04/04/89)
Here (and perhaps 'most everyewhere) Ed's posting ended thusly:
(multiply-hebrew-calendar-interval
hebrew-calendar-leap-year
(prior-leap-years-in-hebr
uxc.cso.uiuc.edu ignored 42 excess bytes
If your copy had this problem, go to the end, back up to the last (defun..., and repolace that with the following:
------------------------------------------------------------------------
(defun hebrew-calendar-new-year-mean-conjunction (year)
"The time of week of the mean conjunction of Tishri of YEAR+3761."
(let ((interval
(add-hebrew-calendar-intervals
hebrew-calendar-epoch
(multiply-hebrew-calendar-interval
hebrew-calendar-cycle
(hebrew-calendar-cycles year))
(multiply-hebrew-calendar-interval
hebrew-calendar-regular-year
(prior-regular-years-in-hebrew-calendar-cycle year))
(multiply-hebrew-calendar-interval
hebrew-calendar-leap-year
(prior-leap-years-in-hebrew-calendar-cycle year)))))
interval))
(defun hebrew-calendar-new-year-day (year)
"Absolute date of 1 Tishri (Rosh Hashanah) of YEAR+3761."
(let* ((m (hebrew-calendar-new-year-mean-conjunction year))
(day (extract-hebrew-calendar-days m))
(hour (extract-hebrew-calendar-hours m))
(part (extract-hebrew-calendar-parts m))
;; Take into account any delay.
(day1
(if (or (>= hour 18)
(and (= (% day 7) 2)
(not (hebrew-calendar-leap-year-p year))
(or (> hour 9)
(and (= hour 9) (>= part 204))))
(and (= (% day 7) 1)
(hebrew-calendar-leap-year-p (1- year))
(or (> hour 15)
(and (= hour 15) (>= part 589)))))
(1+ day)
day)))
(if (memq (% day1 7) (list 0 3 5))
(1+ day1)
day1)))
(defun hebrew-calendar-leap-year-p (year)
"Returns t if YEAR+3761 is a leap year."
(memq
(years-into-hebrew-calendar-cycle year)
(list 0 3 6 8 11 14 17)))
(defun hebrew-calendar-long-heshvan-p (year)
"Returns t if Heshvan is long in YEAR+3761."
(if (hebrew-calendar-leap-year-p year)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 385)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 355)))
(defun hebrew-calendar-short-kislev-p (year)
"Returns t if Kislev is short in YEAR+3761."
(if (hebrew-calendar-leap-year-p year)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 383)
(= (-
(hebrew-calendar-new-year-day (1+ year))
(hebrew-calendar-new-year-day year)) 353)))
(defun hebrew-calendar-last-day-of-month (month year)
"The last day of MONTH in YEAR+3761."
(if (or (memq month (list 2 4 6 10 13))
(and (= month 12) (not (hebrew-calendar-leap-year-p year)))
(and (= month 8) (not (hebrew-calendar-long-heshvan-p year)))
(and (= month 9) (hebrew-calendar-short-kislev-p year)))
29
30))
(defun hebrew-calendar-date-beyond-date (days month year)
"Returns the Hebrew date that is DAYS beyond the start of MONTH, YEAR+3761.
That date must be in the same year."
(let ((len (hebrew-calendar-last-day-of-month month year)))
(while (> days len)
(setq days (- days len))
(setq month (1+ (% month (hebrew-calendar-last-month-of-year year))))
(setq len (hebrew-calendar-last-day-of-month month year))))
(list days month year))
(defun hebrew-calendar-days-from-tishri (days month year)
"Number of days, inclusive, from 1 Tishri to DAYS, MONTH, YEAR+3761."
(while (/= month 7)
(setq month
(if (= month 1)
(hebrew-calendar-last-month-of-year year)
(1- month)))
(setq days (+ days (hebrew-calendar-last-day-of-month month year))))
days)
(defun hebrew-calendar-year-length (year)
"The number of days in Hebrew calendar YEAR+3761."
(- (hebrew-calendar-new-year-day year)
(hebrew-calendar-new-year-day (1- year))))
(defun hebrew-calendar-last-month-of-year (year)
"The last month of the Hebrew calendar YEAR+3761."
(if (hebrew-calendar-leap-year-p year)
13
12))
(defun calendar-absolute-from-hebrew (date)
"Absolute date of Hebrew DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
(let ((month (extract-calendar-month date))
(day (extract-calendar-day date))
(year (- (extract-calendar-year date) 3761)))
(+
-1
(hebrew-calendar-new-year-day year)
(hebrew-calendar-days-from-tishri day month year))))
------------------------------------------------------------------------
/jr
jr@bbn.com or bbn!jr
C'mon big money!wombat@claris.com (Scott Lindsey) (04/05/89)
From article <4300041@m.cs.uiuc.edu>, by reingold@m.cs.uiuc.edu: [most of calendar.el deleted...] > (multiply-hebrew-calendar-interval > hebrew-calendar-leap-year > (prior-leap-years-in-hebr > > uxc.cso.uiuc.edu ignored 42 excess bytes So... could someone repost? -- Scott Lindsey |"Cold and misty morning. I heard a warning borne in the air Claris Corp. | About an age of power when no one had an hour to spare" ames!claris!wombat| DISCLAIMER: These are not the opinions of Claris, Apple, wombat@claris.com | StyleWare, the author, or anyone else living or dead.
reingold@m.cs.uiuc.edu (10/13/89)
I am planning to clean up a number of minor items in calendar.el, the online calendar/diary package, in the next few weeks and I would appreciate hearing (via email) from any users with suggestions, complaints, or problems. For those of you who do not have the package and want to try it, it is available from a.cs.uiuc.edu by anonymous ftp; it's in /pub/calendar.el. Thanks. Ed Reingold (reingold@cs.uiuc.edu)
ron@mlfarm.uucp (Ronald Florence) (10/01/90)
The function calendar-cursor-to-date() in Edward M. Reingold
(reingold@cs.uiuc.edu)'s calendar.el announces
(args-out-of-range 555 558) when the various calendar
movement commands are used on September 30, 1990. The
functions seem to work other days of the year. It is
obvious that the layout of the calendar is a little
different that year (the cursor is on the only date in the
bottom line of the buffer). Any idea how to fix what seems
like a bug? Thanks.
--
Ronald Florence {hsi,rayssd}!mlfarm!ronnuge@ctmed@gemed.ge.com (James A. Nugent) (10/05/90)
In article <RON.90Sep30220147@mlfarm.uucp> ron@mlfarm.uucp (Ronald Florence) writes: > The function calendar-cursor-to-date() in Edward M. Reingold > (reingold@cs.uiuc.edu)'s calendar.el announces > (args-out-of-range 555 558) when the various calendar > movement commands are used on September 30, 1990. The > functions seem to work other days of the year. It is > obvious that the layout of the calendar is a little > different that year (the cursor is on the only date in the > bottom line of the buffer). Any idea how to fix what seems > like a bug? Thanks. I must have an older version because mine doesn't even have that function in it, and I can't reproduce your specific problem or suggest an exact fix. I suspect that the "put the cursor on date" function is being confused by tabs in the buffer. I do remember having to change it because the analagous function in my version "broke" in February 1989. In goto-visible-date (in my version), I changed a forward-char () to move-to-column (). The latter understands tabs; the former doesn't. Maybe that's your problem. -- Jim Nugent