[comp.sys.hp] DOWNLOADING FILES FROM HP3000

dipto@umbc3.UMD.EDU (Dipto Chakravarty) (03/19/88)

We wish to download a bunch of files (100+ in number and 15Mb+
in size) from a HP3000 (running MPE/V) to a HP Vectra PC (with
MS-DOS 3.2).

Does anybody have any experience with the Reflections and the 
AdvanceLink software ? A method to make this mass file trasfer
using either of the above software will be much appreciated. 

Kindly reply by e-mail. Regards.

Dipto Chakravarty
Unix/Communications Consultant
Computer Center, U. of Maryland


-- 
BITNET : dipto@umbc.BITNET    ------\
ARPANET: dipto@umbc3.UMD.EDU  -------> In-real-life: Dipto Chakravarty
USMAIL : CMSC, UMBC,Md 21228  ------/

stephens@hpcupt1.HP.COM (Greg Stephens) (03/23/88)

Let me know how this Reflection Command file works for you:

============================================================

close printer

;  v1 = MPE Filespec
;  v2 = PC Pathname
;  v3 = Labels ([A]ll, [B]inary, [N]one)
;  v4 = [A]ppend, [D]elete, Do[N]'t
;  v5 = Temp counter/pos

;  v6 = MPE File Name & ASCII/BINARY
;  v7 = MPE Group Name
;  v8 = MPE Account Name

;  v9 = LISTF Line to be parsed

display "^M^JMPE filespec of files to be downloaded (wildcards allowed):"
accept v1
display "^M^J^M^JFull PC directory/path to download to (end in back slash or ':'):"
accept v2
display "^J^M^JDownload with the labels ';L' option on for:^M^J"
display "[B]inary files, [A]ll files, or [N]o files:"
accept v3
display "^M^J^JIf the file you are downloading to exists, do you want to:^M^J^J"
display "[D]elete the file, [A]ppend to the file, or Do[N]'t download the"
display "file:"
accept v4
display "^M^J^J
;del rgs1.rgs
;del rgs2.rgs
open rgs1.rgs
log
transmit "listf "
transmit v1
transmit ",1^M"
ptransmit "^M"
log off
close disk
open rgs1.rgs input as 1
open rgs2.rgs output as 2
let v5 = v2 & "upload.cmd"
open $5 output as 3

:nextrec
read 1 v9
;display v9
;display "^M^J"

if EOF(1) 
   goto execute
endif

if mid(v9,1,1) = "^M" or mid(v9,1,1) = " " or mid(v9,1,5) = "listf"
   goto nextrec
endif

if mid(v9,1,14) = "FILENAME  CODE" 
   goto nextrec
endif

if find("GROUP=  ",v9) <> 0 and find("ACCOUNT=  ",v9) <> 0 
   goto getacct
endif

let v6 = mid(v9,1,8)
let v6 = pack(v6)
let v5 = "RECEIVE " & v2 & v6

if mid(v9,26,26) = "B"
   let v5 = v5 & ".3k "
else
   let v5 = v5 & ".txt "
endif

let v5 = v5 & "FROM " & v6 & "." & v7 & "." & v8

if mid(v9,26,26) = "B"
   let v6 = "BINARY "
else
   let v6 = "ASCII "
endif
let v3 = upper(v3)
if (v3 = "A") or (v3 = "B" and v6 = "BINARY ")
   let v5 = v5 & ";L"
endif
let v5 = v5 & " " & v6
let v4 = upper(v4)
if v4 = "A"
   let v5 = v5 & "APPEND"
endif 
if v4 = "D"
   let v5 = v5 & "DELETE"
endif
let v5 = v5 & "^M^J"
write 2 v5
let v5 = "SEND" & mid(v5,8,find("FROM",v5)-1) & "TO" & mid(v5,(find("FROM",v5)+4),length(v5))
write 3 v5
goto nextrec

:getacct
let v5 = find("T=",v9)
let v5 = v5 + 4
let v8 = mid(v9,v5,v5+8)
let v8 = pack(v8)

let v5 = find("P=",v9)
let v5 = v5 + 4
let v7 = mid(v9,v5,v5+8)
let v7 = pack(v7)
goto nextrec

:execute
close 1
close 2
close 3
invoke rgs2.rgs
del rgs1.rgs
del rgs2.rgs