ken@HAMLET.CALTECH.EDU (Kenneth Adelman) (08/30/86)
Our VAX 8200 system running VMS V4.4 thinks it is an 8300 as
shown by:
$ WRITE SYS$OUTPUT "''F$GETSYI("NODE_HWTYPE'"
The problem lies in two bugs in the SYSLOA8SS.EXE image. Bug 1 is
that it uses the count of the number of CPUs to make the 8200 vs 8300
determination before it has made the count (so it is checking against
zero CPUs). Bug 2 is that it considers an 8200 to be a machine with 1
or MORE CPUs, and an 8300 with less than 1 CPU.
Could someone else with an 8200 confirm this problem and that
the below patch fixes it? Could someone else with an 8300 confirm
that the below patch doesn't change anything? Anyone with the time
to SPR this please do.
Kenneth Adelman
Caltech
$!
$! Fix two bugs in VMS V4.4 SYSLOA8SS that cause a VAX 8200 to
$! identify itself as a VAX 8300.
$!
$ COPY SYSLOA8SS.EXE SYSLOA8SS.DEC !replace before installing VMS V4.5
$ PATCH SYSLOA8SS
DEFINE INI$IOMAP=188
DEFINE INI$SB_HWTYPE=0B79
DEFINE EXE$INI_TIMWAIT=0B9F
DEFINE INI$CPUNODSP=09E3
!
! In module INITADP8SS, routine INI$IOMAP. Change order of calls to
! INI$SB_HWTYPE and INI$CPUNODSP so INI$SB_HWTYPE is not called until
! AFTER INI$CPUNODSP has counted up the number of CPU nodes.
!
! See VMS V4.4 fiche card 466 I9-J9
!
REPLACE/INSTRUCTION INI$IOMAP+4B
'BSBW INI$SB_HWTYPE'
'BSBW EXE$INI_TIMWAIT'
'BSBW INI$CPUNODSP'
EXIT
'BSBW EXE$INI_TIMWAIT'
'BSBW INI$CPUNODSP'
'BSBW INI$SB_HWTYPE'
EXIT
!
! In module INIADP8SS, routine INI$SB_HWTYPE. Correct reversed
! comparison. 8200s have 1 or less CPUs, not 1 or more.
!
! This mistake was masked by the above one on the VAX 8300.
!
! See VMS V4.4 fiche card 466 H12
!
REPLACE/INSTRUCTION INI$SB_HWTYPE+11
'CMPB #1,@#800022AC'
EXIT
'CMPB @#800022AC,#1'
EXIT
UPDATE
EXIT