badri@ur-valhalla.UUCP (Badri Lokanathan) (08/12/86)
We run BSD4.2 on a VAX11/750.
Has anybody been able to reproduce results obtained with spice2g6
on spice3? I seem to get either errors or differing results with
spice3 on spice decks that work fine with spice2g6; usually
I get a floating point overflow. Could some one run the following
two examples on spice3 and mail me the results? Both work correctly
on spice2g6.
Thank you!
Badri Lokanathan
ARPA : ur-valhalla!badri@rochester.arpa
UUCP : {bullwinkle,cmcl2,columbia,cornell,harvard,ll-xn,
nike,seismo,topaz}!rochester!ur-valhalla!badri
--------------------------- EXAMPLE 1 -----------------------------
Single inverter delay simulation
mpd 1 2 0 3 enh l=5u w=5u
mpu 4 1 1 3 depl l=20u w=5u
cout 1 0 .035p
vin 2 0 pulse (0 5 10ns 1ns 1ns 20ns 50ns)
vdd 4 0 dc 5v
vbb 3 0 dc -2.5v
.tran .5ns 50ns
.plot tran v(2) v(1)
.model enh nmos (vto=.8 kp=35u gamma=.5 phi=.65 lambda=.02 pb=.85
+cgso=.2n cgdo=.2n cgbo=.2n rsh=16 mj=.5 cjsw=.35n mjsw=.33 js=10n
+tox=50n nsub=5e14 nss=5e10 ld=.2u uo=700
+level=1)
.model depl nmos (vto=-3.5 kp=35u gamma=.5 phi=.65 lambda=.02 pb=.85
+cgso=.2n cgdo=.2n cgbo=.2n rsh=16 mj=.5 cjsw=.35n mjsw=.33 js=10n
+tox=50n nsub=5e14 nss=5e10 tpg=1 ld=.2u uo=550
+level=1)
.end
--------------------------- EXAMPLE 2 -----------------------------
RS Flip-Flop simulation
**************************************************************
* NOTE: there is almost no output loading, so response is fast
C1 1 0 .01PF
C2 2 0 .01PF
**************************************************************
M1 9 1 1 0 NDEP W= 5.0U L= 20.0U
M2 9 2 2 0 NDEP W= 5.0U L= 20.0U
M3 1 2 0 0 NENH W= 5.0U L= 5.0U
+ AD= 306.25P
M4 1 3 0 0 NENH W= 5.0U L= 5.0U
+ AD= 306.25P
M5 2 1 0 0 NENH W= 5.0U L= 5.0U
M6 2 4 0 0 NENH W= 5.0U L= 5.0U
*************************************************************
.MODEL NENH NMOS VTO=.8 KP=30.E-6 GAMMA=0.454 NSUB=2.E16
+ UO=800 RSH=0.000 LEVEL=1
+ TOX=.1E-6 CJ=5E-4 PB=.7
.MODEL NDEP NMOS VTO=-3.8 KP=30.E-6 GAMMA=0.454 NSUB=2.E16
+ UO=800 RSH=0.000 LEVEL=1
+ TOX=.1E-6 CJ=5E-4 PB=.7
***NOTE : RSH is set to zero (resistances are negligable)***
***************************************************************
VDD 9 0 DC 5.0
VIN1 3 0 PULSE(0.0 5.0 2NS 2NS 1NS 1.1120NS)
VIN2 4 0 DC 0.0
***************************************************************
.OPTIONS TNOM=25
.IC V(1)=5.0
.TRAN .5N 25N 0N
.WIDTH OUT=80
*.PRINT TRAN V(3) V(2) V(1)
.PLOT TRAN V(1)(0,5) V(2)(0,5) V(3)(0,5)
.END